Подтвердить что ты не робот

Как получить доступ к полям TTestCase в классе TTestSetup

Я создаю модульные тесты с помощью DUnit. У меня есть класс, который занимает довольно много времени для инициализации.

Получается класс TMyTestSetup из TTestSetup и переопределяет его метод установки. Этот метод SetUp вызывается только один раз для всех тестов в моем TTestCase. Я поставил процесс инициализации в подпрограмме TMyTestSetup.SetUp для повышения производительности.

Моя проблема в том, как я могу получить доступ к объекту, который я хочу инициализировать, который является полем моего TMyTest в классе TestSetup? Это единственный способ сделать это, объявив его глобально?

непроверенный короткий пример:

TMyTestSetup = class(TTestSetup)
  protected
    procedure SetUp; override;
end;

TMyTest = class(TTestcase)
public
    fTakes4Ever2Init : TInits4Ever2Init;
published
  procedure Test1;     
end;

implementation

procedure TMyTestSetup.Setup;
begin
   // How can I access fTakes4Ever2Init from here?
  fTakes4Ever2Init.create // This is the call that takes long
end;

procedure TMyTest.Test1;
begin
  fTakes4Ever2Init.DoSomething;
end;

initialization
  RegisterTest(TMyTestSetup.Create(TMyTest.Suite));
4b9b3361

ОТВЕТЫ

Ответ 1

Хитрость заключается в использовании переменной public class в классе TMyTestSetup.

Как этот (проверенный и рабочий, полный) пример:

unit TestTestUnit;

interface

uses
  TestFramework, TestExtensions;

type
  TInits4Ever2Init = class
  private
    FValue: integer;
  public
    constructor Create;
    procedure   DoSomething1;
    procedure   DoSomething2;
    procedure   DoSomething3;
  end;

type
  TMyTestSetup = class(TTestSetup)
  public class var
    fTakes4Ever2Init: TInits4Ever2Init;
  protected
    procedure SetUp; override;
  end;

  TMyTest = class(TTestCase)
  published
    procedure Test1;
    procedure Test2;
    procedure Test3;
  end;

implementation

uses
  SysUtils, Windows;

{ TMyTestSetup }

procedure TMyTestSetup.Setup;
begin
  fTakes4Ever2Init := TInits4Ever2Init.create; // This is the call that takes long
end;

{ TMyTest }

procedure TMyTest.Test1;
begin
  TMyTestSetup.fTakes4Ever2Init.DoSomething1;
end;

procedure TMyTest.Test2;
begin
  TMyTestSetup.fTakes4Ever2Init.DoSomething2;
end;

procedure TMyTest.Test3;
begin
  TMyTestSetup.fTakes4Ever2Init.DoSomething3;
end;

{ TInits4Ever2Init }

constructor TInits4Ever2Init.Create;
begin
  inherited Create;

  // FValue and Format('%p, %d', [Pointer(Self), FValue])) are to confirm
  //   that we are talking to the same object for all the tests,
  //   but that the object is different each time we run the test suite.

  Randomize;
  FValue := Random(10000);

  OutputDebugString(pAnsiChar('-- TInits4Ever2Init.Create: '
    + Format('%p, %d', [Pointer(Self), FValue])));
end;

procedure TInits4Ever2Init.DoSomething1;
begin
  OutputDebugString(pAnsiChar('-- TInits4Ever2Init.DoSomething1: '
    + Format('%p, %d', [Pointer(Self), FValue])));
end;

procedure TInits4Ever2Init.DoSomething2;
begin
  OutputDebugString(pAnsiChar('-- TInits4Ever2Init.DoSomething2: '
    + Format('%p, %d', [Pointer(Self), FValue])));
end;

procedure TInits4Ever2Init.DoSomething3;
begin
  OutputDebugString(pAnsiChar('-- TInits4Ever2Init.DoSomething3: '
    + Format('%p, %d', [Pointer(Self), FValue])));
end;

initialization
  RegisterTest(TMyTestSetup.Create(TMyTest.Suite));
end.

Как показывают комментарии в примере, я использовал рандомизированную закрытую переменную и некоторый вывод отладочной трассировки, чтобы подтвердить, что каждый тестовый вызов с тестовым набором относится к той же копии целевого объекта, но мы получаем другая копия целевого объекта каждый раз, когда запускается тестовый пакет.

Ответ 2

Вы можете получить новый класс Test Suite из класса TTestSuite и переопределить его методы SetUp и TearDown, затем вы можете добавить свои тестовые примеры к этому конкретному набору тестов и зарегистрировать пакет.

Таким образом, методы Setup и TearDown вашего класса набора тестов будут вызываться один раз, а методы SetUp и TearDown для каждого тестового примера будут вызываться для каждого тестового метода, определенного в этом тестовом случае.

Порядок выполнения будет таким:

TestSuite.SetUp;

-- TestCase1.Setup;
---- TestCase1.Test1;
-- TestCase1.TearDown;
-- TestCase1.Setup;
---- TestCase1.Test2;
-- TestCase1.TearDown;

-- TestCase2.Setup;
---- TestCase2.Test1;
-- TestCase2.TearDown;
-- TestCase2.Setup;
---- TestCase2.Test2;
-- TestCase2.TearDown;

-- TestCaseN.Setup;
---- TestCaseN.Test1;
-- TestCaseN.TearDown;
-- TestCaseN.Setup;
---- TestCaseN.Test2;
-- TestCaseN.TearDown;

TestSuite.TearDown;

Ответ 3

Имея только один опубликованный метод, который, в свою очередь, вызывает все ваши другие методы тестирования: ленивый, но более быстрый способ вызова процедуры Setup и TearDown только один раз.

Ответ 4

Вы не можете инициализировать поля TTestCase для всего набора тестов, и вот объяснение, почему:

unit Tests3;

interface

uses
  TestFramework, TestExtensions, Windows, Forms, Dialogs, Controls, Classes,
  SysUtils, Variants, Graphics, Messages;

type
  TMyTestCase = class(TTestCase)
  private
    FValue: Integer;
  published
    procedure Test1;
    procedure Test2;
  end;

implementation

{ TMyTestCase }

procedure TMyTestCase.Test1;
begin
  FValue:= 99;
  ShowMessage(Format('%p, %d', [Pointer(Self), FValue]));
end;

procedure TMyTestCase.Test2;
begin
  ShowMessage(Format('%p, %d', [Pointer(Self), FValue]));
end;

initialization
  RegisterTest(TMyTestCase.Suite);
end.

Если вы запустите выше unit test, вы увидите, что адреса "Self", показанные в тестах1 и Test2, отличаются. Это означает, что экземпляры объекта TMyTestCase различны для вызовов Test1 и Test2.

Следовательно, любые поля, которые вы можете объявить в классе TMyTestCase, являются изменчивыми между вызовами методов тестирования.

Чтобы выполнить "глобальную" инициализацию, вы должны объявить свой объект глобально, а не как поле TMyTestCase.

Ответ 5

Используя TTestSetup, вы можете сделать что-то вроде этого:

type
  TMyTestSetup = class(TTestSetup)
  private
    FValue: Integer;
  protected
    procedure SetUp; override;
    procedure TearDown; override;
  end;

  TMyTestCase = class(TTestCase)
  published
    procedure TestSomething;
  end;

var
  TestSetup: TMyTestSetup;

procedure TMyTestSetup.SetUp;
begin
  inherited;
  TestSetup := Self;
  FValue := 42;
end;

procedure TMyTestSetup.TearDown;
begin
  TestSetup := nil;
  inherited;
end;

procedure TMyTestCase.TestSomething;
begin
  CheckEquals(TestSetup.FValue, 42);
end;

initialization
  TestFramework.RegisterTest(TMyTestSetup.Create(
    TTestSuite.Create('My test suite', [TMyTestCase.Suite])
  ));

Чувствует себя несколько отвратительно, но это делает работу!

Ответ 6

В зависимости от версии Delphi вы можете просто сделать поле TMyTest.fTakes4Ever2Init a public class var, чтобы инициализировать его из тестовой настройки. (Это будет больше стиля ООП по сравнению с глобальной переменной.)