Ограничение полиморфного типа

У меня есть диапазон, определенный как:

type 'a range = Full | Range of ('a * 'a)

Однако я хотел бы ограничить 'a целым числом или float или char, без каких-либо других допустимых типов для' a.

Range(0,10) (* valid *)
Range(0.0, 10.0) (* valid *)
Range('a', 'z') (* valid *)
Range("string1", "string2") (* other types like this shouldn't type check *)

Я решил, что могу изменить свои определения типов:

type sequential   = S_int of int | S_float of float | S_char of char ;;
type range = Full | Range of (sequential * sequential);;

Тем не менее, это позволит сделать что-то вроде:

Range(S_int(0), S_float(10.0));; (* problem: mixes int and float *)

... но я хочу, чтобы оба компонента Range были одного и того же типа.

Я предполагаю, что другой подход заключался бы в создании типа int_range, типа float_range и типа char_range, но мне интересно, есть ли другой способ?

Ответ 1

Взяв намек на то, что сделает Haskell (объявите класс типа (Sequential a) => Range a), вы можете использовать функтор:

module Range (S : sig type t end) = struct
  type range = Full | Range of (S.t * S.t)
end

и использовать его для предоставления необходимых модулей:

module IntRange   = Range (struct type t = int   end)
module FloatRange = Range (struct type t = float end)
module CharRange  = Range (struct type t = char  end)

Недостатком является то, что вы теряете параметричность на range; что ваши параметрические функции на range теперь живут внутри модуля range, как они, вероятно, должны.

В общем случае range выполнит ряд требований Sequential, чтобы компенсировать потерю параметричности. Эти требования могут быть четко определены в сигнатуре параметра functor:

module type SEQUENTIAL = sig
  type t
  val to_string : t -> string
  val compare : t -> t -> int
  (* ... *)
end

module Range (S : SEQUENTIAL) = struct
  type t = Full | Range of (S.t * S.t)
  let to_string = function
  | Full -> "full"
  | Range (lo, hi) -> "(" ^ S.to_string lo ^ "," ^ S.to_string hi ^ ")"
  let make lo hi =
    if S.compare lo hi > 0 then Range (hi, lo) else Range (lo, hi)
end

Чтобы создать экземпляр range в определенном типе, вам теперь необходимо создать структуру, которая правильно ее параметризует:

module IntRange = Range (struct
  type t = int
  let to_string = string_of_int
  let compare = Pervasives.compare
end)

Затем вы можете использовать его следующим образом:

# IntRange.(to_string (make 4 2)) ;;
- : string = "(2,4)"

(с использованием нового синтаксиса для ограничения перегрузки). Если вам нужно скрыть реализацию range за подписью, вам может потребоваться повторно экспортировать тип Sequential s, как это делают структуры данных в стандартной библиотеке:

module Range (S : SEQUENTIAL) : sig
  type elt = S.t
  type t = private Full | Range of (elt * elt)
  val to_string : t -> string
  val make : elt -> elt -> t
end = struct
  type elt = S.t
  type t = Full | Range of (elt * elt)
  let to_string = function
  | Full -> "full"
  | Range (lo, hi) -> "(" ^ S.to_string lo ^ "," ^ S.to_string hi ^ ")"
  let make lo hi =
    if S.compare lo hi > 0 then Range (hi, lo) else Range (lo, hi)
end

Это дает вам инкапсуляцию и полупрозрачные типы, которые могут быть сопоставлены с образцом, но не сконструированы. Альтернативой объявлению типов private в сигнатуре является использование типа представления или функции деструктурирования.

Ответ 2

Другой подход заключается в том, чтобы объявлять функции типа private и expose, строя их только теми типами, которые вы хотите, например.

module Z : sig
  type 'a range = private Full | Range of ('a * 'a)
  val int_range : int -> int -> int range
  val float_range : float -> float -> float range
  val string_range : string -> string -> string range
  val full : 'a range
end = struct
  type 'a range = Full | Range of ('a * 'a)
  let create x y = Range (x,y)
  let int_range = create
  let float_range = create
  let string_range = create
  let full = Full
end

# open Z;;
# int_range 2 3;;
- : int Z.range = Range (2, 3)
# Range ('a','c');;
Error: Cannot create values of the private type char Z.range

Ответ 3

Модули OMG настолько сложны!

type 'a range' = [`Full | `Range of 'a * 'a]
type range = [
  | `Int_range of int range'
  | `Float_range of float range'
]

Ну, нам нужно добавить еще один:

type xrange = [
  | range
  | `String_range of string range'
]