Как создать графический интерфейс с помощью Lisp: DrScheme или Common Lisp

Ответ 1

Документация для программирования GUI в DrRacket (имя текущей версии DrScheme) находится здесь: http://docs.racket-lang.org/gui/index.html

Поскольку вы читаете HTDP, это, вероятно, лучший вариант для вас прямо сейчас.

Ответ 2

• Если вы хотите просто сделать простой графический интерфейс в Common Lisp, ваш лучший выбор, на мой взгляд, - это LTK, который является высокоуровневым интерфейсом для Библиотека сценариев Tcl/Tk.
• Есть много других вариантов, но они требуют некоторых видение того, чего вы пытаетесь достичь. Если вы хотите использовать один из широко распространенных наборов инструментов GUI (GTK или Qt) - CL-GTK2 и CommonQt. Но вы должны прежде всего хорошо понимать, как эти работа с инструментами
• LispWorks предоставляет очень сложную библиотеку GUI-builder CAPI, который является кросс-платформенным.
• На Mac ClozureCL есть хорошие Cocoa привязки.
• Наконец, полномасштабное собственное решение CL для GUI - McCLIM - который очень гибкий, но довольно привлекательный

Кроме того, если вы хотите понять GUI и изучить его с теоретической точки зрения, вы должны узнать о различных графических интерфейсах GUI, таких как MVC, Model2, MVVM и т.д. Я не знаю ни о какой GUI-структуре в Lisp, реализуя такие шаблоны, поэтому такой проект может быть интересным опытом обучения...

Ответ 3

Там есть легкая библиотека для написания простых графических программ через 2htdp/universe. См. Как создавать миры.

Основная идея заключается в том, что современные графические библиотеки очень ориентированы на события: вы взаимодействуете с внешним миром, реагируя на события. Если вы посмотрите на это достаточно близко, библиотека юниверса представляет собой реализацию модели MVC: мир - это "Модель", "рисовать" "Вид" и все остальные обработчики событий "Контроллер".

Если вы хотите работать с более низкоуровневыми элементами в Racket, вы можете использовать библиотеки racket/gui. Они содержат справочную документацию в Инструментах графического интерфейса Racket. Вот небольшой пример, который использует библиотеку:

#lang racket

(require racket/gui/base
         2htdp/image
         (only-in mrlib/image-core render-image))

;; The state of our program is a number.
(define state 0)

;; On a timer tick, increment the state, and refresh the canvas.
;; tick!: -> void
(define (tick!)
  (set! state (add1 state))
  (send THE-CANVAS refresh))


;; When a canvas paints itself, use the following:
;; paint: canvas% dc<%> -> void
(define (paint! a-canvas my-drawing-context)
  (define my-new-scene (text (format "I see: ~a" state) 20 'black))
  ;; Note: we force the canvas to be of a particular width and height here:
  (send a-canvas min-client-width (image-width my-new-scene))
  (send a-canvas min-client-height (image-height my-new-scene))
  (render-image my-new-scene my-drawing-context 0 0))


;; Here, we initialize our graphical application.  We create a window frame...
;; THE-FRAME: frame%
(define THE-FRAME (new (class frame%
                         (super-new)
                         ;; When we close the frame, shut down everything.
                         (define/augment (on-close)
                           (custodian-shutdown-all (current-custodian))))
                       [label "Example"]))


;; and add a canvas into it.
;; THE-CANVAS: canvas%
(define THE-CANVAS (new (class canvas%
                          (super-new)

                          ;; We define a key handler.  Let have it so it
                          ;; resets the counter on a key press
                          (define/override (on-char key-event)
                            (when (eq? (send key-event get-key-code) 'release)
                              (set! state 0)
                              (send THE-CANVAS refresh))))
                        [parent THE-FRAME]
                        [paint-callback paint!]))

;; We get the frame to show on screen:
(send THE-FRAME show #t)

;; Finally, we set up a timer that will call tick! on every second.
(define THE-TIMER (new timer% 
                       [notify-callback tick!]
                       [interval 1000]))

Ответ 4

В недавней статье о текущем состоянии общей экосистемы Lisp говорится: CommonQt плюс Qtools - это путь в настоящее время.