Delphi от двух до байтового массива

Простой способ преобразования двойного значения в представление байтов? Я пробовал использовать указатели вроде:

var
  double_v:double;
  address:^double;
....
double_v:=100;
address:[email protected]_v;

но все мои понятия: как читать это 8 байт от адреса, заканчивайтесь "AV".

Ответ 1

Два примера использования "абсолютных"...

Используется как функция

function GetDoubleByte(MyDouble: Double; Index: Byte): Byte;
var
  Bytes: array[0..7] of Byte absolute MyDouble;
begin
  Result := Bytes[Index];
end;



procedure TForm1.Button1Click(Sender: TObject);
var
 MyDouble:Double;
 DoubleBytes:Array[0..7] of Byte absolute MyDouble; // direct local use
begin
  MyDouble := 17.123;
  ShowMessage(IntToStr(DoubleBytes[0])); // local usage

  ShowMessage(IntToStr(GetDoubleByte(MyDouble,0))); // via function call

end;

Ответ 2

Используйте вариантную запись

Type
  TDoubleAndBytes = Record
    case boolean of
      false : (dabDouble : Double);
      true  : (dabBytes : Array [0..7] Of Byte);
  end;

Назначьте двойное значение dabDouble и прочитайте байты через dabBytes

var
  myVar : TDoubleAndBytes;
  i : integer;

begin
  myVar.dabDouble := 100;
  for i:=0 to 7 do write(myVar.dabBytes[i]);

Ответ 3

В XE3 для простых типов есть помощники записи, TDoubleHelper.

Это работает:

var
  d : Double;
  i : Integer;
begin
  d := 100.0;
  for i := 0 to 7 do
    WriteLn(d.Bytes[i]);
end;

В XE2 есть объявление TDoubleRec, которое является расширенной записью.

Пример:

var
  dRec : TDoubleRec;
  i : Integer;
begin
  dRec := 100.0;
  for i := 0 to 7 do
    WriteLn(dRec.Bytes[i]);
end;

Другим распространенным вариантом доступа к байтам двойника является использование typecast:

type
  TDoubleAsByteArr = array[0..7] of byte;
var
  d : Double;
  i : Integer;
begin
  d := 100.0;
  for i := 0 to 7 do
    WriteLn(TDoubleAsByteArr(d)[i]);
end;