Почему этот файл заголовка boost не включен

Я создаю свою программу на С++ с помощью cmake на Mac. Компилятор дает мне следующую ошибку:

error: boost/filesystem.hpp: No such file or directory

Линия, вызывающая ошибку, следующая:

#include "boost/filesystem.hpp"

или

#include <boost/filesystem.hpp>

Какое из приведенных выше я не изменил Error

Но в моем CMakeLists.txt я включаю заголовки boost следующим образом:

FIND_PACKAGE(Boost) 
MESSAGE("Boost information:") 
MESSAGE("  Boost_INCLUDE_DIRS: ${Boost_INCLUDE_DIRS}") 
MESSAGE("  Boost_LIBRARIES: ${Boost_LIBRARIES}") 
MESSAGE("  Boost_LIBRARY_DIRS: ${Boost_LIBRARY_DIRS}") 

INCLUDE_DIRECTORIES(${Boost_INCLUDE_DIRS})
LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})

Boost include dirs заполняется "/opt/local/include/" во время процесса cmake, и эта папка содержит расширение папки, которое содержит файловую систему .hpp

Boost предоставляет следующие сообщения при создании Makefile, я только скопировал часть boost:

-- Boost version: 1.38.0
-- Found the following Boost libraries:
Boost information:
Boost_INCLUDE_DIRS: /opt/local/include
Boost_LIBRARIES: 
Boost_LIBRARY_DIRS: /opt/local/lib
-- Configuring done

При запуске make VERBOSE = 1 Эта строка содержит ошибку:

cd /Users/janusz/Documents/workspace/ImageMarker/Debug/src && 
/usr/bin/c++ -O3 -Wall -Wno-deprecated -g -verbose -I/Users/janusz/Documents/workspace/ImageMarker/src/. -o CMakeFiles/ImageMarker.dir/FaceRecognizer.cpp.o -c /Users/janusz/Documents/workspace/ImageMarker/src/FaceRecognizer.cpp
/Users/janusz/Documents/workspace/ImageMarker/src/FaceRecognizer.cpp:8:32: error: boost/filesystem.hpp: No such file or directory
make[2]: *** [src/CMakeFiles/ImageMarker.dir/FaceRecognizer.cpp.o] Error 1

Вы понимаете, почему компилятор не выбирает каталог /opt/local/include?

Если вам нужна дополнительная информация, я рад предоставить ее

Ответ 1

Прежде всего используйте

FIND_PACKAGE(Boost REQUIRED)

а не

  FIND_PACKAGE(Boost)

Таким образом cmake даст вам хорошее сообщение об ошибке, если оно не найдет его, задолго до начала каких-либо компиляций. Если это не удается, установите переменную среды BOOST_ROOT в /opt/local (которая является установочным префиксом). Кроме того, вам придется ссылаться в библиотеке файловой системы, поэтому вы хотите

FIND_PACKAGE(Boost COMPONENTS filesystem REQUIRED)

для последующего использования

target_link_libraries(mytarget ${Boost_FILESYSTEM_LIBRARY})

Enter

cmake --help-module FindBoost

в оболочке, чтобы получить документы для модуля поиска Boost в вашей установке cmake.

PS: Пример

Файл CMakeLists.txt

cmake_minimum_required(VERSION 2.6)
project(Foo)

find_package(Boost COMPONENTS filesystem REQUIRED)

include_directories(${Boost_INCLUDE_DIRS})
add_executable(foo main.cpp)
target_link_libraries(foo 
  ${Boost_FILESYSTEM_LIBRARY}
)

main.cpp

#include <boost/filesystem.hpp>
#include <vector>
#include <string>
#include <cstdio>
#include <cstddef>

namespace fs = boost::filesystem;
using namespace std;

int main(int argc, char** argv)
{
  vector<string> args(argv+1, argv+argc);
  if(args.empty())
  {
    printf("usage: ./foo SOME_PATH\n");
    return EXIT_FAILURE;
  }

  fs::path path(args.front());

  if(fs::exists(path))
    printf("%s exists\n", path.string().c_str());
  else
    printf("%s doesn't exist\n", path.string().c_str());

  return EXIT_SUCCESS;
}

Ответ 2

Вы пытались включить filesystem.hpp без части "boost/"?

Ответ 3

Я решил аналогичную проблему, добавив некоторые строки в мой CMakeLists.txt.

cmake_minimum_required(VERSION 3.5)
project(MyResource)

function(myresources out_var)
    set(RESULT)
    foreach(in_f ${ARGN})
        file(RELATIVE_PATH src_f ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/${in_f})
        set(out_f "${PROJECT_BINARY_DIR}/${in_f}.c")
        add_custom_command(OUTPUT ${out_f}
                COMMAND myresource ${out_f} ${src_f}
                DEPENDS ${in_f}
                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
                COMMENT "Building binary file for ${out_f}"
                VERBATIM)
        list(APPEND result ${out_f})
    endforeach()
    set(${out_var} "${result}" PARENT_SCOPE)
endfunction()

find_package(Boost COMPONENTS filesystem REQUIRED)
find_path(BOOST_FILESYSTEM_INCLUDE_DIRS boost/filesystem.hpp)

add_executable(myresource myresource.cpp)
target_link_libraries(myresource ${Boost_FILESYSTEM_LIBRARY} ${Boost_SYSTEM_LIBRARY})
target_include_directories(myresource PUBLIC ${BOOST_FILESYSTEM_INCLUDE_DIRS})