Подтвердить что ты не робот

Как использовать Inno Setup для обновления базы данных с помощью .sql script

Я хотел бы скомпилировать установку, которая будет подключаться к удаленной базе данных с использованием учетных данных, предоставленных пользователем, а затем установить несколько компонентов db с помощью .sql script.

Возможно ли это с помощью Inno Setup?

Подробнее:

Я хотел бы иметь пользовательскую форму, прося пользователя ввести адрес и учетные данные базы данных, а затем запустить команду, которая будет выполнять sql script, который будет обновлять удаленный сервер базы данных.

Если обновление выполнено успешно, завершите установку с успехом.

Это довольно общий вопрос: у меня есть множество настраиваемых настроек, которые должны подключаться к разным серверам/запускать разные сценарии. Идея состоит в том, чтобы создать общую форму, которая обеспечит эту функциональность.

4b9b3361

ОТВЕТЫ

Ответ 1

Я не думаю, что вы можете иметь полностью общую форму, так как для разных серверов вам может понадобиться одна строка соединения или имя сервера и (необязательный) порт; для некоторых серверов вы будете использовать системную аутентификацию, для других - кортеж паролей имени пользователя.

Сказав, что я дам вам небольшую демо Inno script, которая запрашивает имя и порт сервера, имя пользователя и пароль, затем выполняет несколько тестов, затем выполняет приложение, которое извлекается (по коду) на temp и будет удален установщиком. Вы можете использовать это как отправную точку для своих скриптов. Наличие нескольких таких фрагментов и включение их в ваши скрипты по мере необходимости, вероятно, будет всем, что вам нужно:

[Setup]
AppID=DBUpdateTest
AppName=Test
AppVerName=Test 0.1
AppPublisher=My Company, Inc.
DefaultDirName={pf}\Test
DefaultGroupName=Test
DisableDirPage=yes
DisableProgramGroupPage=yes
OutputBaseFilename=setup
PrivilegesRequired=none

[Files]
Source: "isql.exe"; DestDir: "{tmp}"; Flags: dontcopy
Source: "update_V42.sql"; DestDir: "{tmp}"; Flags: dontcopy

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Code]
var
  DBPage: TInputQueryWizardPage;

procedure InitializeWizard;
begin
  DBPage := CreateInputQueryPage(wpReady,
    'Database Connection Information', 'Which database is to be updated?',
    'Please specify the server and the connection credentials, then click Next.');
  DBPage.Add('Server:', False);
  DBPage.Add('Port:', False);
  DBPage.Add('User name:', False);
  DBPage.Add('Password:', True);

  DBPage.Values[0] := GetPreviousData('Server', '');
  DBPage.Values[1] := GetPreviousData('Port', '');
  DBPage.Values[2] := GetPreviousData('UserName', '');
  DBPage.Values[3] := GetPreviousData('Password', '');
end;

procedure RegisterPreviousData(PreviousDataKey: Integer);
begin
  SetPreviousData(PreviousDataKey, 'Server', DBPage.Values[0]);
  SetPreviousData(PreviousDataKey, 'Port', DBPage.Values[1]);
  SetPreviousData(PreviousDataKey, 'UserName', DBPage.Values[2]);
  SetPreviousData(PreviousDataKey, 'Password', DBPage.Values[3]);
end;

function NextButtonClick(CurPageID: Integer): Boolean;
var
  ResultCode: Integer;
begin
  Result := True;
  if CurPageID = DBPage.ID then begin
    if DBPage.Values[0] = '' then begin
      MsgBox('You must enter the server name or address.', mbError, MB_OK);
      Result := False;
    end else if DBPage.Values[2] = '' then begin
      MsgBox('You must enter the user name.', mbError, MB_OK);
      Result := False;
    end else if DBPage.Values[3] = '' then begin
      MsgBox('You must enter the user password.', mbError, MB_OK);
      Result := False;
    end else begin
      ExtractTemporaryFile('isql.exe');
      ExtractTemporaryFile('update_V42.sql');
      if Exec(ExpandConstant('{tmp}') + '\isql.exe', '--user ' + DBPage.Values[2]
        + ' --password ' + DBPage.Values[3] + ' --database ' + DBPage.Values[0]
        + ':foo --script update_V42.sql', '',
        SW_HIDE, ewWaitUntilTerminated, ResultCode)
      then begin
        // check ResultCode and set Result accordingly
        Result := ResultCode = 0;
      end else begin
        MsgBox('Database update failed:'#10#10 + SysErrorMessage(ResultCode),
          mbError, MB_OK);
        Result := False;
      end;
    end;
  end;
end;

Остерегайтесь: я не полностью протестировал это, поэтому может потребоваться больше кода для правильной очистки всего. Обработка ошибок, безусловно, отсутствует!