Получить родительское имя каталога для определенного файла с помощью DOS Batch scripting

Ответ 1

см. этот вопрос

@echo OFF
set mydir="%~p1"
SET mydir=%mydir:\=;%

for /F "tokens=* delims=;" %%i IN (%mydir%) DO call :LAST_FOLDER %%i
goto :EOF

:LAST_FOLDER
if "%1"=="" (
    @echo %LAST%
    goto :EOF
)

set LAST=%1
SHIFT

goto :LAST_FOLDER

Ответ 2

Первый ответ выше не работает, если имя родительского каталога содержит пробел. Следующие работы:

@echo off
setlocal

set ParentDir=%~p1
set ParentDir=%ParentDir: =:%
set ParentDir=%ParentDir:\= %
call :getparentdir %ParentDir%
set ParentDir=%ParentDir::= %

echo ParentDir is %ParentDir%
goto :EOF

:getparentdir
if "%~1" EQU "" goto :EOF
Set ParentDir=%~1
shift
goto :getparentdir

Вызов вышеуказанного с параметром "C:\Temp\Parent Dir With Space\myfile.txt" дает следующее:

>GetParentDir "C:\Temp\Parent Dir With Space\myfile.txt"
ParentDir is Parent Dir With Space

Вышеупомянутые работы заменяют пробелы двоеточиями (они не должны существовать в путях Windows), затем заменяя разделители каталога пробелами, чтобы отдельные каталоги передавались в getparentdir как отдельные аргументы. Функция getparentdir петли, пока не найдет свой последний аргумент. Наконец, любые двоеточия в результате заменяются пробелами.

Ответ 3

Очень легко получить родительскую папку командного файла:

@echo off
for %%a in ("%~dp0\.") do set "parent=%%~nxa"
echo %parent%

И для родителя пути файла в соответствии с вопросом:

@echo off
for %%a in ("c:\test\pack\a.txt") do for %%b in ("%%~dpa\.") do set "parent=%%~nxb"
echo %parent%

Ответ 4

вы можете использовать vbscript, например, сохранить ниже как getpath.vbs

Set objFS = CreateObject("Scripting.FileSystemObject")
Set objArgs = WScript.Arguments
strFile = objArgs(0)
WScript.Echo objFS.GetParentFolderName(strFile)

затем в командной строке или в вашей партии, сделайте это

C:\test>cscript //nologo getpath.vbs c:\test\pack\a.txt
c:\test\pack

Если вы хотите пакетный метод, вы можете посмотреть for /?.

  %~fI        - expands %I to a fully qualified path name
  %~dI        - expands %I to a drive letter only
  %~pI        - expands %I to a path only

Ответ 5

Вот способ, который не использует CALL, и я считаю, что это быстрее. Основано на функции разделения jeb (может завершиться неудачно, если имя каталога содержит !):

@echo off

set "mydir=%~p1"
SET mydir=%mydir:~0,-1%

setlocal EnableDelayedExpansion
set LF=^


rem ** Two empty lines are required

for %%L in ("!LF!") DO (
    set "dir_name=!mydir:\=%%L!"
)
for /f "delims=" %%P in (""!dir_name!"") do set "dn=%%~P"
echo %dn%

exit /b 0 

Ответ 6

Я обнаружил, что эта комбинация подходов из ответов djangofan и paranoid является как простой, так и вполне достаточной при поиске родительского каталога script:

set FULL_PATH=%~dp0
set FULL_PATH=%FULL_PATH:~1,-1%
for %%i in ("%FULL_PATH%") do set "PARENT_FOLDER=%%~ni"
echo %PARENT_FOLDER%

Так как вы хотите работать с пользовательским вводом, вам нужно выполнить некоторую минимальную дополнительную работу, чтобы обрабатывать правовые вариации, такие как C:\foo\bar\a.txt и C:\foo\bar\a.txt или с:/foo/bar/a.txt. Это может сработать для вас:

@setlocal
@echo off

call:GET_PARENT_FOLDER C:\foo\bar\a.txt
echo %PARENT_FOLDER%
call:GET_PARENT_FOLDER C:\foo\bar\\a.txt
echo %PARENT_FOLDER%
call:GET_PARENT_FOLDER c:/foo/bar/a.txt
echo %PARENT_FOLDER%

pause
goto:EOF

:GET_PARENT_FOLDER
:: Strip the filename, so we get something like this: 'C:\foor\bar\'
set "_FULL_PATH=%~dp1"

:: Strips all dangling '\' and '/' in a loop, so the last folder name becomes accessible
:_STRIP
if not "%_FULL_PATH:~-1%"=="\" if not "%_FULL_PATH:~-1%"=="/" goto:_STRIP_END
set "_FULL_PATH=%_FULL_PATH:~1,-1%"
goto:_STRIP
:_STRIP_END

:: We need the context of a for-loop for the special path operators to be available
for %%i in ("%_FULL_PATH%") do set "PARENT_FOLDER=%%~ni"

goto:EOF

Ответ 7

Идея DaDummy разработана в более практичных многоразовых функциях. Также включен первый символ _full_path.

set map=D:\test1\test2\test3\test4.txt
call:get_parent_path "%map%"
echo full_path is %_full_path%
call:get_parent_path %_full_path%
echo full_path is %_full_path%
call:get_last_path %_full_path%
echo last_path is %_last_path%
goto :eof

:get_parent_path
set "_full_path=%~dp1"
:_strip
if not "%_full_path:~-1%"=="\" if not "%_full_path:~-1%"=="/" goto:_strip_end
set "_full_path=%_full_path:~0,-1%"
goto:_strip
:_strip_end
exit /b

:get_last_path
set "_last_path=%~nx1"
exit /b

::result:
::full_path is D:\test1\test2\test3
::full_path is D:\test1\test2
::last_path is test2

Ответ 8

Вот еще одно решение:

SET LAST=%CD%
SET PARENTNAME=NONE
cd /D C:\test\pack
FOR %%I in (%CD%) do SET PARENTNAME=%%~nI
cd /D %LAST%
ECHO %PARENTNAME%

%% ~ nI: '~ n' извлекает имя из пути, хранящегося в переменной %% я переменной
Параметр cd: '/D' добавлен для переключения между дисками также