Значения аргументов по умолчанию в подпрограммах

Ответ 1

Я делаю это с именованными аргументами так:

sub hello {
    my (%arg) = (
        'foo' => 'default_foo',
        'bar' => 'default_bar',
        @_
    );

}

Я верю Params::Validate поддерживает значения по умолчанию, но это больше проблем, чем мне нравится.

Ответ 2

Обычно я делаю что-то вроде:

sub hello {
    my ($say,$to) = @_;
    $say ||= "Hello";
    $to ||= "World!";
    print "$say $to\n";
}

Обратите внимание, что начиная с perl 5.10 вы можете использовать оператор "//=", чтобы проверить, определена ли переменная, а не просто отличная от нуля. (Предположим, что вызов hello("0","friend"), который с использованием приведенного выше даст "Hello friend", что может быть не так, как вы хотели. Используя оператор //=, он даст "0 friend").

Ответ 3

Также посмотрите Method::Signatures. Это использует Devel::Declare, чтобы предоставить дополнительный (необходимый!) Сахар с ключевыми словами method и func.

Ниже приведен ваш пример с использованием нового func:

use Method::Signatures;

func hello ($say='Hello', $to='World!') {
    say "$say $to";
}

hello( 'Hello', 'you!' );    # => "Hello you!"
hello( 'Yo' );               # => "Yo World!"
hello();                     # => "Hello World!"

/I3az/

Ответ 4

Поскольку механизм Perl для передачи аргументов в подпрограммы является одним списком, аргументы являются позиционными. Это затрудняет предоставление значений по умолчанию. Некоторые встроенные модули (например, substr) обрабатывают это путем упорядочивания аргументов в зависимости от того, насколько они вероятны для использования - менее часто используемые аргументы появляются в конце и имеют полезные значения по умолчанию.

Более чистый способ сделать это - использовать именованные аргументы. Perl не поддерживает именованные аргументы как таковые, но вы можете имитировать их с помощью хэшей:

use 5.010;  # for //

sub hello {
    my %arg = @_;
    my $say = delete $arg{say} // 'Hello';
    my $to  = delete $arg{to}  // 'World!';
    print "$say $to\n";
}

hello(say => 'Hi', to => 'everyone');  # Hi everyone
hello(say => 'Hi');                    # Hi world!
hello(to  => 'neighbor Bob');          # Hello neighbor Bob
hello();                               # Hello world!

Примечание. Определенный или оператор // был добавлен в Perl v5.10. Он более надежный, чем использование логического или (||), поскольку он не будет по умолчанию для логически ложных значений '' и 0.

Ответ 5

Если вы видите документацию Perl Best Practices: Значения по умолчанию по Дамиан Конвей, то вы найдете несколько важных моментов, таких как:

• Разрешите любые значения аргументов по умолчанию, как только @_ распакуется.
• Предполагается, что если у вас есть множество значений по умолчанию для настройки, то самый чистый способ будет факторировать значения по умолчанию в таблицах, т.е. хеш, а затем предварительно инициализировать хэш хэша с этой таблицей.

Пример:

#!/usr/bin/perl
  use strict;
  use warning;
  my %myhash = (say => "Hello", to => "Stack Overflow");
  sub hello {
   my ($say, $to) = @_;
   $say =  $say ? $say : $myhash{say};
   $to =  $to ? $to : $myhash{to};
   print "$say $to\n";
  }
  hello('Perl');      # output :Perl Stack Overflow
  hello('','SO');     # output :Hello SO
  hello('Perl','SO'); # output :Perl SO
  hello();            # output :Hello Stack Overflow

Для более подробного и полного примера обратитесь к Perl Best Practices.

Ответ 6

В модуле CPAN находится Атрибут:: Default. Вероятно, более чистый, чем этот, и избегает нескольких сложностей (например, что, если вы хотите передать false в свою подпрограмму?).

Я также видел, как люди использовали my $var = exists @_[0] ? shift : "Default_Value";, но документация Perl отмечает, что вызов exists на массивах устарел, поэтому я не рекомендовал бы это.

Фрагмент Attribute::Default на странице документа:

  sub vitals : Default({age => 14, sex => 'male'}) {
     my %vitals = @_;
     print "I'm $vitals{'sex'}, $vitals{'age'} years old, and am from $vitals{'location'}\n";
  }

   # Prints "I'm male, 14 years old, and am from Schenectady"
   vitals(location => 'Schenectady');

Ответ 7

Лучший способ решить вашу проблему обсуждался в других ответах.
Одна вещь, которая меня поражает, заключается в том, что вы заявляете, что:

sub hello {
   print @_ || "Hello world";
}

И это отлично работает, если вам нужен только один аргумент.

Вы действительно пробовали этот код? Он напечатает количество аргументов или, если их не будет, Hello World!
Причина этого в том, что || -оператор имеет приоритет и заставляет левую сторону в скалярном контексте, тем самым уменьшая @_ до количества аргументов, которые вы предоставляете, а не самих аргументов!
посмотрите perlop для получения дополнительной информации об операторах на Perl.

НТН,
Пол

Ответ 8

Больше сахара см. также Method::Signatures:

func add($this = 23, $that = 42) {
    return $this + $that;
}