Подтвердить что ты не робот

Получить полный путь от PID, используя delphi

Мне нужно получить полный путь от PID, я проверяю этот вопрос С++ Windows - Как получить путь к процессу из его PID

и я написал этот код

 function GetFullPathFromPID(PID: DWORD): string;
 var
    hProcess: THandle;
    ModName : Array[0..MAX_PATH + 1] of Char;
 begin
   Result:='';
    hProcess := OpenProcess(PROCESS_ALL_ACCESS,False, PID);
    try
      if hProcess <> 0 then
       if GetModuleFileName(hProcess, ModName, Sizeof(ModName))<>0 then
         Result:=ModName
        else
         ShowMessage(SysErrorMessage(GetLastError));
    finally
     CloseHandle(hProcess);
    end;
 end;

но всегда возвращайте это сообщение

указанный модуль не может быть найдено

как я могу вернуть полный путь из pid?

4b9b3361

ОТВЕТЫ

Ответ 1

Вам нужно использовать функцию GetModuleFileNameEx. Из MSDN:

Функция GetModuleFileName

Извлекает полный путь к файлу который содержит указанный модуль. Модуль должен быть загружен текущий процесс.

Найти файл для модуля, который был загружен другим процессом, используйте Функция GetModuleFileNameEx.

Использование образца (uses PsAPI):

function GetPathFromPID(const PID: cardinal): string;
var
  hProcess: THandle;
  path: array[0..MAX_PATH - 1] of char;
begin
  hProcess := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, false, PID);
  if hProcess <> 0 then
    try
      if GetModuleFileNameEx(hProcess, 0, path, MAX_PATH) = 0 then
        RaiseLastOSError;
      result := path;
    finally
      CloseHandle(hProcess)
    end
  else
    RaiseLastOSError;
end;