Оптимизация хвостового опциона F # с 2 рекурсивными вызовами?

Как я писал эту функцию, я знал, что не буду оптимизировать хвостовой вызов. Я до сих пор не придумал хороший способ справиться с этим, и надеялся, что кто-то может предложить предложения.

У меня есть дерево:

type Heap<'a> =
| E
| T of int * 'a * Heap<'a> * Heap<'a>

И я хочу подсчитать, сколько узлов в нем:

let count h =
    let rec count' h acc =
        match h with 
        | E -> 0 + acc
        | T(_, value, leftChild, rightChild) ->
            let acc = 1 + acc
            (count' leftChild acc) + (count' rightChild acc)

    count' h 0

Это не оптимизировано из-за добавления счетчиков для дочерних узлов. Любая идея о том, как сделать что-то подобное, работает, если дерево имеет 1 миллион узлов?

Спасибо, Дерек

Вот реализация счетчика с использованием CPS. Тем не менее, он все еще взорвал стек.

let count h =
    let rec count' h acc cont =
        match h with
        | E -> cont (1 + acc)
        | T(_,_,left,right) ->
            let f = (fun lc -> count' right lc cont)
            count' left acc f

    count' h 0 (fun (x: int) -> x)

Может быть, я могу придумать какой-нибудь способ разделить дерево на достаточно кусочки, которые я могу считать, не выдувая стек?

Кто-то спросил о коде, который генерирует дерево. Он ниже.

member this.ParallelHeaps threads =
    let rand = new Random()
    let maxVal = 1000000

    let rec heaper i h =
        if i < 1 then
            h
        else
            let heap = LeftistHeap.insert (rand.Next(100,2 * maxVal)) h
            heaper (i - 1) heap

    let heaps = Array.create threads E
    printfn "Creating heap of %d elements, with %d threads" maxVal threads
    let startTime = DateTime.Now
    seq { for i in 0 .. (threads - 1) ->
          async { Array.set heaps i (heaper (maxVal / threads) E) }}
    |> Async.Parallel
    |> Async.RunSynchronously 
    |> ignore

    printfn "Creating %d sub-heaps took %f milliseconds" threads (DateTime.Now - startTime).TotalMilliseconds
    let startTime = DateTime.Now

    Array.length heaps |> should_ equal threads <| "The size of the heaps array should match the number of threads to process the heaps"

    let rec reMerge i h =
        match i with 
        | -1 -> h
        | _  -> 
            printfn "heap[%d].count = %d" i (LeftistHeap.count heaps.[i])
            LeftistHeap.merge heaps.[i] (reMerge (i-1) h)

    let heap = reMerge (threads-1) E
    printfn "Merging %d heaps took %f milliseconds" threads (DateTime.Now - startTime).TotalMilliseconds
    printfn "heap min: %d" (LeftistHeap.findMin heap)

    LeftistHeap.count heap |> should_ equal maxVal <| "The count of the reMerged heap should equal maxVal"

Ответ 1

Вы можете использовать стиль продолжения (CPS) для решения этой проблемы. См. Рекурсия по рекурсии - Продолжение передачи Мэтью Подвиски.

let tree_size_cont tree = 
  let rec size_acc tree acc cont = 
    match tree with 
    | Leaf _ -> cont (1 + acc) 
    | Node(_, left, right) -> 
         size_acc left acc (fun left_size -> 
         size_acc right left_size cont) 

  size_acc tree 0 (fun x -> x)

Обратите также внимание на то, что в сборке Debug оптимизация вызовов вызовов отключена. Если вы не хотите работать в режиме Release, вы можете включить оптимизацию в свойствах проекта в Visual Studio.

Ответ 2

CPS - хорошее общее решение, но вам также может потребоваться явное использование стека, потому что оно будет быстрее и, возможно, проще:

let count heap =
  let stack = System.Collections.Generic.Stack[heap]
  let mutable n = 0
  while stack.Count > 0 do
    match stack.Pop() with
    | E -> ()
    | T(_, _, heap1, heap2) ->
        n <- n + 1
        stack.Push heap1
        stack.Push heap2
  n