Подтвердить что ты не робот

F # Как скомпилировать кодовую цитату в сборку

Я хотел бы знать, есть ли способ скомпилировать кодовую цитату в сборку?

Я понимаю, что на объект Exp<_> можно вызвать CompileUntyped() или Compile(), например:

let x = <@ 1 * 2 @>
let com = x.Compile()

Однако, как я могу сохранить com на диск как сборку?

Спасибо.

Ответ 1

Вы можете оценить котировки кода F # с совпадением шаблонов:

open Microsoft.FSharp.Quotations.Patterns

let rec eval  = function
    | Value(v,t) -> v
    | Call(None,mi,args) -> mi.Invoke(null, evalAll args)
    | arg -> raise <| System.NotSupportedException(arg.ToString())
and evalAll args = [|for arg in args -> eval arg|]

let x = eval <@ 1 * 3 @>

Смотрите F # PowerPack, Unquote, Foq Проекты OSS или этот фрагмент для более полных реализаций.

Для компиляции котировки кода F # вы можете определить динамический метод с помощью Reflection.Emit:

open System.Reflection.Emit

let rec generate (il:ILGenerator) = function
    | Value(v,t) when t = typeof<int> ->
        il.Emit(OpCodes.Ldc_I4, v :?> int)
    | Call(None,mi,args) -> 
        generateAll il args
        il.EmitCall(OpCodes.Call, mi, null)
    | arg -> raise <| System.NotSupportedException(arg.ToString())
and generateAll il args = for arg in args do generate il arg

type Marker = interface end

let compile quotation =
    let f = DynamicMethod("f", typeof<int>, [||], typeof<Marker>.Module)
    let il = f.GetILGenerator()
    quotation |> generate il
    il.Emit(OpCodes.Ret)
    fun () -> f.Invoke(null,[||]) :?> int

let f = compile <@ 1 + 3 @>
let x = f ()

Чтобы скомпилировать сборку, используйте Reflection.Emit для создания типа с помощью метода:

open System
open System.Reflection

let createAssembly quotation =
    let name = "GeneratedAssembly"
    let domain = AppDomain.CurrentDomain
    let assembly = domain.DefineDynamicAssembly(AssemblyName(name), AssemblyBuilderAccess.RunAndSave)
    let dm = assembly.DefineDynamicModule(name+".dll")
    let t = dm.DefineType("Type", TypeAttributes.Public ||| TypeAttributes.Class)
    let mb = t.DefineMethod("f", MethodAttributes.Public, typeof<int>, [||])
    let il = mb.GetILGenerator()
    quotation |> generate il
    il.Emit(OpCodes.Ret)
    assembly.Save("GeneratedAssembly.dll")

createAssembly <@ 1 + 1 @>

Для более полной реализации смотрите проект Fil (от F # до IL).