Как вы можете получить текущую таблицу в MS Word VBA?

Я хочу иметь возможность запускать модуль VBA, который манипулирует таблицей, в которой я сейчас (т.е. курсор находится где-то внутри этой таблицы). Код VBA будет выполнять идентичную операцию для каждой таблицы, в которой вы находитесь, когда вы ее запускаете.

Итак, допустим, допустим, у меня есть модуль, который должен был смещать верхнюю строку каждой таблицы (заголовки). Ему нужно будет найти объект таблицы (называемый whatever), который вы сейчас используете, чтобы он мог манипулировать whatever.rows(0).

Как я могу получить объект таблицы из позиции курсора? Мне также нужно определить, нет ли я в таблице и ничего не делать (или поднять диалоговое окно с ошибкой).

Ответ 1

Подпрограмма VBA в нижней части этого ответа показывает, как это сделать.

Он использует текущий выбор, сначала сбрасывая его в исходную точку, чтобы не беспокоиться о выборе нескольких сегментов:

Selection.Collapse Direction:=wdCollapseStart

Затем он проверяет этот выбор для обеспечения его внутри таблицы

    If Not Selection.Information(wdWithInTable) Then
        MsgBox "Can only run this within a table"
        Exit Sub
    End If

Затем таблица доступна для обращения к Selection.Tables(1).

Приведенный ниже код был простым доказательством концепции, которое просто переключило каждую из начальных ячеек в каждой строке таблицы, чтобы либо вставить, либо удалить маркер вертикальной строки.

Sub VertBar()
    ' Collapse the range to start so as to not have to deal with '
    ' multi-segment ranges. Then check to make sure cursor is '
    ' within a table. '
    Selection.Collapse Direction:=wdCollapseStart
    If Not Selection.Information(wdWithInTable) Then
        MsgBox "Can only run this within a table"
        Exit Sub
    End If

    ' Process every row in the current table. '
    Dim row As Integer
    Dim rng As Range

    For row = 1 To Selection.Tables(1).Rows.Count
        ' Get the range for the leftmost cell. '
        Set rng = Selection.Tables(1).Rows(row).Cells(1).Range

        ' For each, toggle text in leftmost cell. '
        If Left(rng.Text, 2) = "| " Then
            ' Change range to first two characters and delete them. '
            rng.Collapse Direction:=wdCollapseStart
            rng.MoveEnd Unit:=wdCharacter, Count:=2
            rng.Delete
        Else
            ' Just insert the vertical bar. '
            rng.InsertBefore ("| ")
        End If
    Next
End Sub

Ответ 2

Я понимаю, что это довольно старый вопрос, но я наткнулся на какой-то код, который может помочь следующему человеку, столкнувшись с аналогичной проблемой.

ActiveDocument.Range(0, Selection.Tables(1).Range.End).Tables.count

Это вернет индекс таблицы, в которую находится курсор. Который может быть использован для внесения изменений или получения информации:

dim numberOfColumnsInCurrentTable as Integer
dim currentTableIndex as Integer

currentTableIndex = ActiveDocument.Range(0, Selection.Tables(1).Range.End).Tables.count
numberOfColumns = ActiveDocument.Tables(currentTableIndex).Columns.count

Очевидно, что необходимо добавить проверки, чтобы курсор находился внутри таблицы.