Закругленная форма с системной тенью

Ответ 1

Вот пример кода, как установить область окна с тенью:
(Примечания: Форма BorderStyle считается bsNone, а не повторно значимой)

type
TForm1 = class(TForm)
  procedure FormCreate(Sender: TObject);
private
  procedure CreateFlatRoundRgn;
protected
  procedure CreateParams(var Params: TCreateParams); override;
public
end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure ExcludeRectRgn(var Rgn: HRGN; LeftRect, TopRect, RightRect, BottomRect: Integer);
var
  RgnEx: HRGN;
begin
  RgnEx := CreateRectRgn(LeftRect, TopRect, RightRect, BottomRect);
  CombineRgn(Rgn, Rgn, RgnEx, RGN_OR);
  DeleteObject(RgnEx);
end;

procedure TForm1.CreateFlatRoundRgn;
const
  CORNER_SIZE = 6;
var
  Rgn: HRGN;
begin
  with BoundsRect do
  begin
    Rgn := CreateRoundRectRgn(0, 0, Right - Left + 1, Bottom - Top + 1, CORNER_SIZE, CORNER_SIZE);
    // exclude left-bottom corner
    ExcludeRectRgn(Rgn, 0, Bottom - Top - CORNER_SIZE div 2, CORNER_SIZE div 2, Bottom - Top + 1);
    // exclude right-bottom corner
    ExcludeRectRgn(Rgn, Right - Left - CORNER_SIZE div 2, Bottom - Top - CORNER_SIZE div 2, Right - Left , Bottom - Top);
  end;
  // the operating system owns the region, delete the Rgn only SetWindowRgn fails
  if SetWindowRgn(Handle, Rgn, True) = 0 then
    DeleteObject(Rgn);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  BorderStyle := bsNone;
  CreateFlatRoundRgn;
end;

procedure TForm1.CreateParams(var Params: TCreateParams);
const
  CS_DROPSHADOW = $00020000;
begin
  inherited CreateParams(Params);
  with Params do
  begin
    Style := WS_POPUP;
    WindowClass.Style := WindowClass.Style or CS_DROPSHADOW;
  end;
end;

Другим способом рисования пользовательской тени было бы установить Window WS_EX_LAYERED и использовать UpdateLayeredWindow

Вот очень хороший пример того, как это делается (источники находятся на С++, но очень легко понять)

Для более сложных фигур вы можете использовать PNG изображение в форме и Alpha Blend it.

EDIT:

Изменение размера окна WS_POPUP - это мир боли... У вас есть несколько вариантов:

• Напишите обработчик WM_NCHITEST
• Используйте WM_Syscommand $F008 для изменения размера (выше ссылки) или $F012 до переместите окно.
• Использование WS_EX_STATICEDGE и WS_SIZEBOX.

ПРИМЕЧАНИЕ, что вам нужно заново создать область окна при ее изменении размера (например, OnResize событие).