Clojure эквивалент Python encode ('hex') и декодирование ('hex')

Ответ 1

Я считаю, что ваша функция unhexify такая же идиоматическая, как и может быть. Однако hexify можно записать более простым способом:

(defn hexify [s]
  (format "%x" (new java.math.BigInteger (.getBytes s))))

Ответ 2

Ваша реализация (и) не работает для символов, отличных от ascii,

(defn hexify [s]
  (apply str
    (map #(format "%02x" (int %)) s)))

(defn unhexify [hex]
  (apply str
    (map 
      (fn [[x y]] (char (Integer/parseInt (str x y) 16))) 
        (partition 2 hex))))

(= "\u2195" (unhexify(hexify "\u2195")))
false ; should be true 

Чтобы преодолеть это, вам нужно сериализовать байты строки, используя требуемую кодировку символов, которая может быть многобайтной на символ.

Есть несколько "проблем" с этим.

• Помните, что все числовые типы подписаны в JVM.
• Нет байта без знака.

В идиоматическом java вы должны использовать младший байт целого числа и маскировать его так, как вы его использовали.

    int intValue = 0x80;
    byte byteValue = (byte)(intValue & 0xff); -- use only low byte

    System.out.println("int:\t" + intValue);
    System.out.println("byte:\t" + byteValue);

    -- output:
    -- int:   128
    -- byte:  -128

clojure имеет (unchecked-byte), чтобы эффективно сделать то же самое.

Например, используя UTF-8, вы можете сделать это:

(defn hexify [s]
  (apply str (map #(format "%02x" %) (.getBytes s "UTF-8"))))

(defn unhexify [s]
  (let [bytes (into-array Byte/TYPE
                 (map (fn [[x y]]
                    (unchecked-byte (Integer/parseInt (str x y) 16)))
                       (partition 2 s)))]
    (String. bytes "UTF-8")))

; with the above implementation:

;=> (hexify "\u2195")
"e28695"
;=> (unhexify "e28695")
"↕"
;=> (= "\u2195" (unhexify (hexify "\u2195")))
true

Ответ 3

Поскольку все опубликованные решения имеют некоторые недостатки, я делюсь своими:

(defn hexify "Convert byte sequence to hex string" [coll]
  (let [hex [\0 \1 \2 \3 \4 \5 \6 \7 \8 \9 \a \b \c \d \e \f]]
      (letfn [(hexify-byte [b]
        (let [v (bit-and b 0xFF)]
          [(hex (bit-shift-right v 4)) (hex (bit-and v 0x0F))]))]
        (apply str (mapcat hexify-byte coll)))))

(defn hexify-str [s]
  (hexify (.getBytes s)))

и

(defn unhexify "Convert hex string to byte sequence" [s] 
      (letfn [(unhexify-2 [c1 c2] 
                 (unchecked-byte 
                   (+ (bit-shift-left (Character/digit c1 16) 4)
                      (Character/digit c2 16))))]
     (map #(apply unhexify-2 %) (partition 2 s))))

(defn unhexify-str [s]
  (apply str (map char (unhexify s)))) 

Плюсы:

• Высокая производительность
• Общий поток байтовых потоков ↔ преобразований строк со специализированными обертками
• Обработка начального нуля в шестнадцатеричном результате