Копирование значений из одного хэша в другой в perl

У меня есть два хэша, один большой и один маленький. Все меньшие хэш-ключи отображаются в большем хеше, но значения разные. Я хочу скопировать значения из большего хэша в меньший хэш.

например:.

# I have two hashes like so
%big_hash = (A => '1', B => '2', C => '3', D => '4', E => '5');
%small_hash = (A => '0', B => '0', C => '0');
# I want small_hash to get the values of big_hash like this
%small_hash = (A => '1', B => '2', C => '3');

Очевидным ответом было бы перебрать ключи небольшого хэша и скопировать значения, подобные этому

foreach $key (keys %small_hash) { $small_hash{$key} = $big_hash{$key}; }

Есть ли более короткий способ сделать это?

Ответ 1

@small_hash{ keys %small_hash } = @big_hash{ keys %small_hash };

Ответ 2

Здесь вы можете сделать это:

%small = map { $_, $big{$_} } keys %small;

Altho, что очень похоже на цикл for.

$small{$_} = $big{$_} for keys %small;

map proof для тех, кому это нужно:

my %big = (A => '1', B => '2', C => '3', D => '4', E => '5');
my %small = (A => '0', B => '0', C => '0');

%small = map { $_, $big{$_} } keys %small;

print join ', ', %small;

Вывод:

A, 1, C, 3, B, 2

Ответ 3

use strict;
my %source = ( a =>  1, b => 2, c => 3 );
my %target = ( a => -1, x => 7, y => 9 );

# Use a hash slice for the copy operation.
# Note this will clobber existing values.
# Which is probably what you intend here.
@target{ keys %source } = values %source;

for ( sort keys %target ) {
  print $_, "\t", $target{ $_ }, "\n";
}