После этого добавьте интерфейс в класс

Ответ 1

Вы можете сохранить возможность сохранения данных и реализовать их через наследование и по-прежнему создавать правильные экземпляры для ClassGUID, хранящихся в таблицах, если вы примените factory шаблон дизайна.

Для каждого класса node должен быть один класс factory (или просто указатель на функцию), ответственный за создание правильного класса Delphi. Заводы класса могут регистрироваться в секции инициализации устройства (один раз при запуске приложения) на объекте singleton ядра.

Ядро singleton затем сопоставило бы GUID, чтобы исправить factory, который в свою очередь вызовет правильный конструктор экземпляра класса (как показано на http://delphipatterns.blog.com/2011/03/23/abstract-factory)

Пакеты могут быть разделены на отдельные библиотеки DLL и классы, реализованные в отдельных единицах, все еще наследуемых от одного базового класса TVMNode.

Функции, которые вы используете RTTI для, могут быть легко доступны в классах потомков или в классах factory с помощью некоторых виртуальных методов.

Вы также можете использовать более простой Объекты передачи данных для сохранения/загрузки TVMNodes и, возможно, вдохнуть вдохновение в уже хорошо воспринимаемый Объект Relational Mapper или Объектно-ориентированная структура как проблема, которую вы пытаются решить, как мне кажется, именно те проблемы, с которыми они справляются (уже)

Я не знаю о хороших фреймах с открытым исходным кодом Delphi этого класса. Но с других языков вы можете посмотреть Java Hibernate, Microsoft.NET Entity Framework или минималистичный Сериализатор буферов протоколов Google

Ответ 2

Да, это возможно.

Мы реализовали нечто подобное, чтобы получить контроль над глобальными/синглтонами для целей тестирования. Мы изменили наши синглтоны на доступность в качестве интерфейсов приложения (не TApplication, наш собственный эквивалент). Затем мы добавили возможность динамически добавлять/удалять интерфейсы во время выполнения. Теперь наши тестовые примеры могут подключать подходящие макеты по мере необходимости.

Я опишу общий подход, надеюсь, вы сможете применить его к особенностям вашей ситуации.

• Добавить поле для хранения списка динамически добавленного интерфейса. TInterfaceList работает красиво.
• Добавить методы добавления/удаления динамических интерфейсов.
• Переопределить function QueryInterface(const IID: TGUID; out Obj): HResult; virtual;. Ваша реализация сначала проверит список интерфейсов, и если не найден, будет отложена базовая реализация.

Изменить: Пример кода

Чтобы ответить на ваш вопрос:

Я понимаю, что теперь класс может сказать другим, что он теперь поддерживает интерфейс X, поэтому интерфейс был добавлен во время выполнения. Но мне также нужно ОСУЩЕСТВИТЬ методы интерфейса извне (другое устройство). Как это делается?

При добавлении интерфейса вы добавляете экземпляр объекта, который реализует интерфейс. Это очень похоже на обычное свойство ... реализует <interface> чтобы делегировать реализацию интерфейса другому объекту. Главное различие заключается в динамическом. Таким образом, он будет иметь такие же ограничения: например. нет доступа к "хозяину", если явно не указана ссылка.

Следующий тестовый пример DUnit демонстрирует упрощенную версию метода в действии.

unit tdDynamicInterfaces;

interface

uses
  SysUtils,
  Classes,
  TestFramework;

type
  TTestDynamicInterfaces = class(TTestCase)
  published
    procedure TestUseDynamicInterface;
  end;

type
  ISayHello = interface
    ['{6F6DDDE3-F9A5-407E-B5A4-CDF91791A05B}']
    function SayHello: string;
  end;

implementation

{ ImpGlobal }

type
  TDynamicInterfaces = class(TInterfacedObject, IInterface)
  { We must explicitly state that we are implementing IInterface so that
    our implementation of QueryInterface is used. }
  private
    FDynamicInterfaces: TInterfaceList;
  protected
    function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
  public
    constructor Create;
    destructor Destroy; override;
    procedure AddInterface(AImplementedInterface: IInterface);
  end;

type
  TImplementor = class (TInterfacedObject, ISayHello)
  { NOTE: This could easily have been implemented in a separate unit. }
  protected
    {ISayHello}
    function SayHello: string;
  end;

{ TDynamicInterfaces }

procedure TDynamicInterfaces.AddInterface(AImplementedInterface: IInterface);
begin
  { The simplest, but least flexible approach (see also QueryInterface).
    Other options entail tagging specific GUIDs to be associated with given
    implementation instance. Then it becomes feasible to check for duplicates
    and also dynamically remove specific interfaces. }
  FDynamicInterfaces.Add(AImplementedInterface);
end;

constructor TDynamicInterfaces.Create;
begin
  inherited Create;
  FDynamicInterfaces := TInterfaceList.Create;
end;

destructor TDynamicInterfaces.Destroy;
begin
  FDynamicInterfaces.Free;
  inherited Destroy;
end;

function TDynamicInterfaces.QueryInterface(const IID: TGUID; out Obj): HResult;
var
  LIntf: IInterface;
begin
  { This implementation basically means the first implementor added will be 
    returned in cases where multiple implementors support the same interface. }
  for LIntf in FDynamicInterfaces do
  begin
    if Supports(LIntf, IID, Obj) then
    begin
      Result := S_OK;
      Exit;
    end;
  end;

  Result := inherited QueryInterface(IID, Obj);
end;

{ TImplementor }

function TImplementor.SayHello: string;
begin
  Result := 'Hello. My name is, ' + ClassName;
end;

{ TTestDynamicInterfaces }

procedure TTestDynamicInterfaces.TestUseDynamicInterface;
var
  LDynamicInterfaceObject: TDynamicInterfaces;
  LInterfaceRef: IUnknown;
  LFriend: ISayHello;
  LActualResult: string;
begin
  LActualResult := '';

  { Use ObjRef for convenience to not declare interface with "AddInterface" }
  LDynamicInterfaceObject := TDynamicInterfaces.Create;
  { But lifetime is still managed by the InterfaceRef. }
  LInterfaceRef := LDynamicInterfaceObject;

  { Comment out the next line to see what happens when support for 
    interface is not dynamically added. }
  LDynamicInterfaceObject.AddInterface(TImplementor.Create);

  if Supports(LInterfaceRef, ISayHello, LFriend) then
  begin
    LFriend := LInterfaceRef as ISayHello;
    LActualResult := LFriend.SayHello;
  end;

  CheckEqualsString('Hello. My name is, TImplementor', LActualResult);
end;

end.