CMake - зависимости (заголовки) между приложениями/библиотеками в одном проекте

У меня есть следующая структура проекта:

CMakeLists.txt
- lib1/CMakeLists.txt и все файлы cpp и заголовков lib
- lib2/CMakeLists.txt и все файлы cpp и заголовков lib
- app/CMakeLists.txt и все файлы cpp и заголовков приложения

Основной CMakeLists.txt выглядит так:

PROJECT( ${PROJECT_NAME} )
add_subdirectory(lib1)
add_subdirectory(lib2)
add_subdirectory(app)

Файл lib1/CMakeLists.txt выглядит, например, как (снято):

SET(SOURCE
file.cpp
)
SET(HEADERS
    some_lib_header.h
)
add_library( lib1 ${SOURCE} ${HEADERS} )

а приложение для приложения выглядит одинаково, кроме ADD_EXECUTABLE:

SET(SOURCE
main.cpp
)
SET(HEADERS
    some_header.h
)
add_library( lib1 ${SOURCE} ${HEADERS} )
ADD_EXECUTABLE( app ${SOURCE} ${HEADERS} )

Я нашел, что настройка работает хорошо, потому что из этого я могу создать один файл решения Visual Studio, содержащий все эти три проекта. Но моя проблема в том, что мое приложение включает в себя файлы заголовков lib1 (а также lib2, который зависит от lib1). Когда я делаю

$mkdir build
$cd build
$cmake -C ..\myproject

он генерирует файл VS.sln вне источника, как я этого хочу, но приложение не компилируется, потому что оно не может найти файлы заголовков lib1 (очевидно).

Теперь я читал и пробовал много вещей, например TARGET_LINK_LIBRARIES( app lib1 ) (который получил приложение для связи с lib1, но не решил проблему с заголовком), и такие вещи, как add_subdirectory( ../lib1 ) в различных вариантах в CMakeLists.txt из приложение (которое все забросило ошибки, которые я не смог исправить), а также find_package (что, я думаю, неверный подход).

Итак, как я могу решить эту проблему (я думаю, простая...)?

Ответ 1

Здесь одно из возможных решений:

Root CMakeLists.txt:

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(${PROJECT_NAME})
add_subdirectory(lib1)
add_subdirectory(lib2)
add_subdirectory(app)

lib1/CMakeLists.txt:

project(Lib1)
add_library(lib1 lib1.cpp lib1.h)

lib2/CMakeLists.txt:

project(Lib2)
add_library(lib2 lib2.cpp lib2.h)

# Add /lib1 to #include search path
include_directories(${Lib1_SOURCE_DIR})
# Specify lib2 dependency on lib1
target_link_libraries(lib2 lib1)

Приложение /CMakeLists.txt:

project(App)
add_executable(app main.cpp some_header.h)

# Add /lib1 and /lib2 to #include search path
include_directories(${Lib1_SOURCE_DIR} ${Lib2_SOURCE_DIR})
# Specify app dependency on lib2.
# lib2 dependency on lib1 is automatically added.
target_link_libraries(app lib2)

Существует множество различных способов достижения такого же конечного результата. Для относительно небольшого проекта я, вероятно, просто использовал бы один CMakeLists.txt:

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(Test)

add_library(lib1 lib1/lib1.cpp lib1/lib1.h)
add_library(lib2 lib2/lib2.cpp lib2/lib2.h)
add_executable(app app/main.cpp app/some_header.h)

include_directories(${CMAKE_SOURCE_DIR}/lib1 ${CMAKE_SOURCE_DIR}/lib2)

target_link_libraries(lib2 lib1)
target_link_libraries(app lib2)

Для получения дополнительной информации о соответствующих командах и их обосновании выполните:

cmake --help-command add_subdirectory
cmake --help-command include_directories
cmake --help-command target_link_libraries

Ответ 2

Project
 CMakeLists.txt
 \-lib1
   CMakeLists.txt
   \- include \ lib1
   \- src
 \-lib2
   CMakeLists.txt
   \- include \ lib2
   \- src
 \-app
   CMakeLists.txt
   \- src

Предположим, что зависимости следующие:

lib1 ---> lib2 ---> app 
   \--------------> app

Что-то вроде этого:

CMakeLists.txt:

add_subdirectory(lib1)
add_subdirectory(lib2)
add_subdirectory(app)

lib1/CMakeLists.txt:

  file(GLOB_RECURSE _HDRS "include/*.hpp")
  file(GLOB_RECURSE _SRCS "src/*.[hc]pp")
  add_library(lib1 ${_HDRS} ${_SRCS})
  #target_link_libraries(lib1)
  target_include_directories(lib1 PUBLIC include)

  install(TARGETS lib1 DESTINATION lib)
  install(FILES ${_HDRS} DESTINATION include/lib1)

lib2/CMakeLists.txt:

  file(GLOB_RECURSE _HDRS "include/*.hpp")
  file(GLOB_RECURSE _SRCS "src/*.[hc]pp")
  add_library(lib2 ${_HDRS} ${_SRCS})
  target_link_libraries(lib2 lib1)
  target_include_directories(lib2 PUBLIC include)

  install(TARGETS lib2 DESTINATION lib)
  install(FILES ${_HDRS} DESTINATION include/lib2)

поэтому в lib2/src/file.cpp вы можете сделать #include <lib1/header.hpp>

app/CMakeLists.txt:

  file(GLOB_RECURSE _SRCS "src/*.[hc]pp")
  add_executable(app ${_SRCS})
  target_link_libraries(app lib1 lib2)

  install(TARGETS app DESTINATION bin)

поэтому в app/src/file.cpp вы можете сделать #include <lib1/header.hpp> и #include <lib2/header.hpp>

Магия target_include_directories, которая прикрепляет каталог "include" к цели, поэтому при связывании с ней вы также включаете каталог include;)