Подтвердить что ты не робот

Почему этот оператор карты в Perl не компилируется?

Это не удается:

my @a = ("a", "b", "c", "d", "e");
my %h = map { "prefix-$_" => 1 } @a;

с этой ошибкой:

Not enough arguments for map at foo.pl line 4, near "} @a"

но это работает:

my @a = ("a", "b", "c", "d", "e");
my %h = map { "prefix-" . $_ => 1 } @a;

почему?

4b9b3361

Ответ 1

Поскольку Perl угадывает EXPR (например, хеш-ссылку) вместо BLOCK. Это должно работать (обратите внимание на символ "+" ):

my @a = ("a", "b", "c", "d", "e");
my %h = map { +"prefix-$_" => 1 } @a;

См. http://perldoc.perl.org/functions/map.html.

Ответ 2

Я предпочитаю писать это как

my %h = map { ("prefix-$_" => 1) } @a;

чтобы показать намерение, что я возвращаю список из 2 элементов.

Ответ 3

От perldoc -f map:

           "{" starts both hash references and blocks, so "map { ..."
           could be either the start of map BLOCK LIST or map EXPR, LIST.
           Because perl doesn’t look ahead for the closing "}" it has to
           take a guess at which its dealing with based what it finds just
           after the "{". Usually it gets it right, but if it doesn’t it
           won’t realize something is wrong until it gets to the "}" and
           encounters the missing (or unexpected) comma. The syntax error
           will be reported close to the "}" but you’ll need to change
           something near the "{" such as using a unary "+" to give perl
           some help:

             %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
             %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
             %hash = map { ("\L$_", 1) } @array  # this also works
             %hash = map {  lc($_), 1  } @array  # as does this.
             %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
             %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)

           or to force an anon hash constructor use "+{"

             @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end

           and you get list of anonymous hashes each with only 1 entry.

Ответ 4

Также, чтобы сделать то, что вы делаете, инициализируя хэш, вы можете сделать вот так:

my @a = qw( a b c d e );
my %h;
@h{@a} = ();

Это создаст записи undef для каждого из пяти ключей. Если вы хотите дать им все истинные значения, сделайте это.

@h{@a} = (1) x @a;

Вы также можете сделать это явно с помощью цикла;

@h{$_} = 1 for @a;

Ответ 5

Я думаю, что

map { ; "prefix-$_" => 1 } @a;

является более идиоматическим, если указать, что это блок операторов, а не хэш-код. Вы просто пинаете его нулевым утверждением.