Как преобразовать xml и сохранить символы новой строки?

Я пытаюсь сохранить разрывы строк в XML файле при преобразовании его в html, но я не могу найти способ, который работает.

<meta>
    <name>Message</name>
    <value>Hi!

    I need info!

    Mr Test</value>
</meta>

И я использую этот xsl:

  <xsl:if test="name='Message'">
  <tr>
    <th align="left" colspan="2">Message:</th>
  </tr>
  <tr>
    <td colspan="2"><xsl:value-of select="value"/></td>
  </tr>
  </xsl:if>

Но новые символы (cr/lf) исчезают, и все становится одной строкой в html. Возможно ли совместить cr/lf и заменить их на html "< _br > " или любым другим способом?

Ответ 1

Добавьте в свой XSL следующий шаблон: -

<xsl:template name="LFsToBRs">
    <xsl:param name="input" />
    <xsl:choose>
        <xsl:when test="contains($input, '&#10;')">
            <xsl:value-of select="substring-before($input, '&#10;')" /><br />
            <xsl:call-template name="LFsToBRs">
                <xsl:with-param name="input" select="substring-after($input, '&#10;')" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$input" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Теперь замените, где выберите значение с вызовом этого шаблона: -

<td colspan="2">
    <xsl:call-template name="LFsToBRs">
        <xsl:with-param name="input" select="value"/>
    </xsl:call-template>
</td>

Ответ 2

Приветствуем, если у вас уже есть LF или CR в исходном xml (похоже, у вас есть), попробуйте ввести стиль "white-space: pre".

то есть:

<div style="white-space: pre;">
  <xsl:value-of select="value"/>
</div>