Разница во времени в секундах

Ответ 1

В perl всегда есть несколько способов сделать что-то. Здесь тот, который использует только модуль, который поставляется с Perl:

#! perl -w

use strict;
use Time::Local;

my $d1 = "Feb 3 12:03:20";
my $d2 = "Feb 4 00:00:30";

# Your date formats don't include the year, so
# figure out some kind of default.
use constant Year => 2012;


# Convert your date strings to Unix/perl style time in seconds
# The main problems you have here are:
# * parsing the date formats
# * converting the month string to a number from 1 to 11
sub convert
{
    my $dstring = shift;

    my %m = ( 'Jan' => 0, 'Feb' => 1, 'Mar' => 2, 'Apr' => 3,
            'May' => 4, 'Jun' => 5, 'Jul' => 6, 'Aug' => 7,
            'Sep' => 8, 'Oct' => 9, 'Nov' => 10, 'Dec' => 11 );

    if ($dstring =~ /(\S+)\s+(\d+)\s+(\d{2}):(\d{2}):(\d{2})/)
    {
        my ($month, $day, $h, $m, $s) = ($1, $2, $3, $4, $5);
        my $mnumber = $m{$month}; # production code should handle errors here

        timelocal( $s, $m, $h, $day, $mnumber, Year - 1900 );
    }
    else
    {
        die "Format not recognized: ", $dstring, "\n";
    }
}

my $t1 = convert($d1);
my $t2 = convert($d2);

print "Diff (seconds) = ", $t2 - $t1, "\n";

Чтобы сделать это действительно готовым к производству, ему нужна лучшая обработка года (например, что происходит, когда дата начала в декабре и дата окончания в январе?) и лучшая обработка ошибок (например, что происходит, если 3- char аббревиатура месяца неправильно введена?).

Ответ 2

#!/usr/bin/perl

$Start = time();
sleep 3;
$End = time();
$Diff = $End - $Start;

print "Start ".$Start."\n";
print "End ".$End."\n";
print "Diff ".$Diff."\n";

Это простой способ найти разницу во времени в секундах.

Ответ 3

Кажется, есть удобный Date::Parse. Вот пример:

use Date::Parse;

print str2time ('Feb 3 12:03:20') . "\n";

И вот что он выводит:

$ perl test.pl
1328288600

который: Fri Feb 3 12:03:20 EST 2012

Я не уверен, насколько хорош синтаксический анализ, но он отлично разбирает ваш пример:)

Ответ 4

В духе TMTOWTDI вы можете использовать ядро ​​Time:: Piece:

#!/usr/bin/env perl
use strict;
use warnings;
use Time::Piece;
my $when = "@ARGV" or die "'Mon Day HH:MM:SS' expected\n";
my $year = (localtime)[5] + 1900;
my $t = Time::Piece->strptime( $year . q( ) . $when, "%Y %b %d %H:%M:%S" );
print "delta seconds = ", time() - $t->strftime("%s"),"\n";

$./mydelta 3 февраля 12:03:20

delta seconds = 14553

Текущий год принимается и берется с вашего локального времени.

Ответ 5

Предполагая, что вы хотите использовать Date:: Calc, преобразуйте два значения в значения "time" с помощью Date_to_Time и вычтите значения для получить разницу в секундах. Но для этого вам нужно преобразовать из строк в значения YY MM DD hh mm ss, чтобы перейти к Date_to_Time.