Как отслеживать операции ввода-вывода для каждого файла в Linux?

Ответ 1

Во-первых, вам, вероятно, не нужно отслеживать, потому что отображение между fd и path доступно в /proc/PID/fd/.

Во-вторых, возможно, вы должны использовать трюк LD_PRELOAD и перегрузку в системных вызовах C open, seek и read. Есть несколько статей здесь и там о том, как перегружать malloc/свободно.

Я думаю, это не будет слишком сильно, чтобы применить тот же трюк для этих системных вызовов. Он должен быть реализован в C, но он должен принимать гораздо меньше кода и быть более точным, чем анализ strace вывода.

Ответ 2

Вы можете дождаться открытия файлов, чтобы вы могли узнать fd и приложить strace после запуска процесса следующим образом:

strace -p pid -e trace = file -e read = fd

Ответ 3

systemtap - это своего рода повторная реализация DTrace для Linux - может быть здесь полезной.

Как и в случае с strace, у вас есть только fd, но с возможностью сценариев легко поддерживать имя файла для fd (если только с забавными вещами, такими как dup). Существует пример script iotime, который illustates его.

#! /usr/bin/env stap

/*
 * Copyright (C) 2006-2007 Red Hat Inc.
 * 
 * This copyrighted material is made available to anyone wishing to use,
 * modify, copy, or redistribute it subject to the terms and conditions
 * of the GNU General Public License v.2.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 *
 * Print out the amount of time spent in the read and write systemcall
 * when each file opened by the process is closed. Note that the systemtap 
 * script needs to be running before the open operations occur for
 * the script to record data.
 *
 * This script could be used to to find out which files are slow to load
 * on a machine. e.g.
 *
 * stap iotime.stp -c 'firefox'
 *
 * Output format is:
 * timestamp pid (executabable) info_type path ...
 *
 * 200283135 2573 (cupsd) access /etc/printcap read: 0 write: 7063
 * 200283143 2573 (cupsd) iotime /etc/printcap time: 69
 *
 */

global start
global time_io

function timestamp:long() { return gettimeofday_us() - start }

function proc:string() { return sprintf("%d (%s)", pid(), execname()) }

probe begin { start = gettimeofday_us() }

global filehandles, fileread, filewrite

probe syscall.open.return {
  filename = user_string($filename)
  if ($return != -1) {
    filehandles[pid(), $return] = filename
  } else {
    printf("%d %s access %s fail\n", timestamp(), proc(), filename)
  }
}

probe syscall.read.return {
  p = pid()
  fd = $fd
  bytes = $return
  time = gettimeofday_us() - @entry(gettimeofday_us())
  if (bytes > 0)
    fileread[p, fd] += bytes
  time_io[p, fd] <<< time
}

probe syscall.write.return {
  p = pid()
  fd = $fd
  bytes = $return
  time = gettimeofday_us() - @entry(gettimeofday_us())
  if (bytes > 0)
    filewrite[p, fd] += bytes
  time_io[p, fd] <<< time
}

probe syscall.close {
  if ([pid(), $fd] in filehandles) {
    printf("%d %s access %s read: %d write: %d\n",
           timestamp(), proc(), filehandles[pid(), $fd],
           fileread[pid(), $fd], filewrite[pid(), $fd])
    if (@count(time_io[pid(), $fd]))
      printf("%d %s iotime %s time: %d\n",  timestamp(), proc(),
             filehandles[pid(), $fd], @sum(time_io[pid(), $fd]))
   }
  delete fileread[pid(), $fd]
  delete filewrite[pid(), $fd]
  delete filehandles[pid(), $fd]
  delete time_io[pid(),$fd]
}

Он работает только с определенным количеством файлов, потому что хэш-карта ограничена по размеру.

Ответ 4

Я думаю, что перегрузка open, seek и read является хорошим решением. Но просто FYI, если вы хотите программно анализировать и анализировать выход strace, я сделал что-то подобное раньше и поместил свой код в github: https://github.com/johnlcf/Stana/wiki

(Я сделал это, потому что мне нужно проанализировать результат strace программы, которой управляют другие, что непросто попросить их сделать LD_PRELOAD.)

Ответ 5

Возможно, наименее уродливый способ сделать это - использовать fanotify. Fanotify - это ядро ​​Linux, которое позволяет дешево смотреть события файловой системы. Я не уверен, разрешает ли он фильтрацию с помощью PID, но он передает PID в вашу программу, чтобы вы могли проверить, интересует ли это тот, который вам интересен.

Вот хороший пример кода: http://bazaar.launchpad.net/~pitti/fatrace/trunk/view/head:/fatrace.c

Однако на данный момент он, по-видимому, недостаточно документирован. Все документы, которые я мог найти, http://www.spinics.net/lists/linux-man/msg02302.html и http://lkml.indiana.edu/hypermail/linux/kernel/0811.1/01668.html

Ответ 6

Разбор командной строки, такой как strace, громоздкий; вместо этого вы можете использовать syscall ptrace(). Подробнее см. man ptrace.