Могу ли я получить результаты хранимой процедуры в курсор в другой хранимой процедуре в SQL

Я пытаюсь помещать результаты хранимой процедуры в курсор для использования в текущей процедуре. Я добавил свой код ниже, но я не уверен, что это возможно или если мой синтаксис верен?

DECLARE cursorIDList CURSOR FOR
    EXEC spGetUserIDs
OPEN cursorIDList

FETCH NEXT FROM cursorIDList INTO @ID

Я получаю следующую ошибку: Неправильный синтаксис рядом с 'EXEC'. Ожидая SELECT, '(' или WITH.

Спасибо заранее.

Ответ 1

Вы можете сделать это следующим образом:

DECLARE @t TABLE (ID INT)
INSERT INTO @t
EXEC spGetUserIDs

DECLARE cursorIDList CURSOR FOR
    SELECT * FROM @t
OPEN cursorIDList

FETCH NEXT FROM cursorIDList INTO @ID

Ответ 2

на мой взгляд очень интересным подходом было бы использовать курсор в качестве параметра (хотя, если вы не собираетесь обновлять таблицу, я не думаю, что это лучший выбор):

create Table dbo.MyTable
(
    i int 
);
Insert Into dbo.MyTable (i) values (1)
Insert Into dbo.MyTable (i) values (2)
Insert Into dbo.MyTable (i) values (3)
Insert Into dbo.MyTable (i) values (4)
Go
Set NoCount ON;
Go
Create Proc dbo.myProc 
(
    @someValue int,
    @cur Cursor Varying Output
)
As
Begin 
    declare @x int;

    Set @cur = Cursor for
        Select i From dbo.MyTable
        Where i < @someValue;

    open @cur
End
Go
-- Use of proc
declare @cur cursor;
declare @x int;
Exec dbo.myProc 3, @cur output


fetch next from @cur into @x
while @@fetch_status = 0
begin
    print 'value: ' + cast(@x as varchar)
    fetch next from @cur into @x
end

close @cur;
Deallocate @cur;

Go
--Cleanup
Drop Proc dbo.myProc 
Drop Table dbo.MyTable

Ответ 3

Синтаксис курсора в SQL-сервере:

DECLARE cursor_name [ INSENSITIVE ] [ SCROLL ] CURSOR FOR select_statement

После FOR вы должны написать SELECT.

Подробнее см.: https://msdn.microsoft.com/it-it/library/ms180169.aspx