Правильный эликсир OTP способ структурировать повторяющиеся задачи

Ответ 1

Я только недавно начал использовать OTP, но я думаю, что могу дать вам несколько указателей:

• Что Elixir способ сделать это, я взял цитату из программирования Elixir Дейвом Томасом, поскольку он объясняет это лучше, чем я:

  Рекурсивная функция приветствия может вас немного беспокоить. каждый время, когда оно получает сообщение, оно в конечном итоге вызывает себя. Во многих языков, который добавляет новый фрейм в стек. После большого количества сообщений, может закончиться нехватка памяти. Это не происходит в Elixir, поскольку он реализует оптимизацию хвостового вызова. Если последнее, что функция is is call сама, theres нет необходимости делать вызов. Вместо этого среда выполнения может просто вернуться к началу функция. Если рекурсивный вызов имеет аргументы, то они заменяют исходные параметры по мере возникновения цикла.

• Задачи (как и в модуле Task) предназначены для одной задачи, короткоживущих процессов, поэтому они могут быть тем, что вы хотите. В качестве альтернативы, почему бы не создать процесс, который порождается (возможно, при запуске), чтобы иметь эту задачу, и иметь ли он цикл и доступ к БД каждые x времени?
• и 4, возможно, посмотрите на использование GenServer со следующей архитектурой. Supervisor → GenServer → Рабочие, которые появляются при необходимости для задачи (здесь вы можете просто использовать spwn fn → ... end, на самом деле не нужно беспокоиться о выборе Task или другого модуля), а затем выйти после завершения.

Ответ 2

Я немного опоздал, но для тех, кто по-прежнему ищет правильный способ сделать это, я думаю, стоит упомянуть документацию GenServer:

handle_info/2 может использоваться во многих ситуациях, например, при обработке сообщений мониторинга DOWN, отправленных Process.monitor/1. Другим вариантом использования handle_info/2 является выполнение периодической работы с помощью Process.send_after/4:

defmodule MyApp.Periodically do
    use GenServer

    def start_link do
        GenServer.start_link(__MODULE__, %{})
    end

    def init(state) do
        schedule_work() # Schedule work to be performed on start
        {:ok, state}
    end

    def handle_info(:work, state) do
        # Do the desired work here
        schedule_work() # Reschedule once more
        {:noreply, state}
    end

    defp schedule_work() do
        Process.send_after(self(), :work, 2 * 60 * 60 * 1000) # In 2 hours
    end
end

Ответ 3

Я думаю, что общепринятым способом делать то, что вы ищете, является подход № 1. Поскольку Erlang и Elixir автоматически оптимизируют tail calls, вам не нужно беспокоиться о переполнении стека.

Ответ 4

Есть другой способ с Stream.cycle. Здесь пример макроса

defmodule Loop do

  defmacro while(expression, do: block) do
    quote do
      try do
        for _ <- Stream.cycle([:ok]) do
          if unquote(expression) do
            unquote(block)
          else
            throw :break
          end
        end
      catch
        :break -> :ok
      end
    end
  end
end

Ответ 5

Я бы использовал GenServer и в init return

{:ok, <state>, <timeout_in_ milliseconds>}

Задание таймаута вызывает вызов функции handle_info при достижении тайм-аута.

И я могу убедиться, что этот процесс запущен, добавив его в мой главный руководитель проекта.

Это пример того, как его можно использовать:

defmodule MyApp.PeriodicalTask do
  use GenServer

  @timeout 50_000 

  def start_link do
    GenServer.start_link(__MODULE__, [], name: __MODULE__)
  end

  def init(_) do
    {:ok, %{}, @timeout}
  end

  def handle_info(:timeout, _) do
    #do whatever I need to do
    {:noreply, %{}, @timeout}
  end
end