Я хотел бы начать работу с ANTLR, но, проведя несколько часов, рассматривая примеры на antlr.org, я все еще не может получить четкое представление о грамматике для процесса Java.
Есть ли какой-то простой пример, что-то вроде калькулятора с четырьмя операциями, реализованного с ANTLR, проходящим через определение парсера и вплоть до исходного кода Java?
Примечание: этот ответ для ANTLR3 ! Если вы ищете пример ANTLR4, тогда в этом разделе " Вопросы и ответы" показано, как создать простой анализатор выражений и вычислитель с использованием ANTLR4.
Сначала вы создаете грамматику. Ниже приведена небольшая грамматика, которую вы можете использовать для оценки выражений, построенных с использованием 4 основных математических операторов: +, -, * и /. Вы также можете группировать выражения, используя круглые скобки.
Обратите внимание, что эта грамматика является очень простой: она не обрабатывает унарные операторы (минус в: -1 + 9) или десятичные числа, такие как .99 (без начального числа), чтобы назвать только два недостатка. Это всего лишь пример, который вы можете работать над собой.
Вот содержимое грамматического файла Exp.g:
grammar Exp;
/* This will be the entry point of our parser. */
eval
: additionExp
;
/* Addition and subtraction have the lowest precedence. */
additionExp
: multiplyExp
( '+' multiplyExp
| '-' multiplyExp
)*
;
/* Multiplication and division have a higher precedence. */
multiplyExp
: atomExp
( '*' atomExp
| '/' atomExp
)*
;
/* An expression atom is the smallest part of an expression: a number. Or
when we encounter parenthesis, we're making a recursive call back to the
rule 'additionExp'. As you can see, an 'atomExp' has the highest precedence. */
atomExp
: Number
| '(' additionExp ')'
;
/* A number: can be an integer value, or a decimal value */
Number
: ('0'..'9')+ ('.' ('0'..'9')+)?
;
/* We're going to ignore all white space characters */
WS
: (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
;
(Правила парсера начинаются со строчной буквы, а правила лексера начинаются с заглавной буквы)
После создания грамматики вы захотите сгенерировать из нее парсер и лексер. Загрузите ANTLR jar и сохраните его в том же каталоге, что и ваш файл грамматики.
Выполните следующую команду в командной оболочке/командной строке:
java -cp antlr-3.2.jar org.antlr.Tool Exp.g
Он не должен выдавать никаких сообщений об ошибках, и теперь должны быть сгенерированы файлы ExpLexer.java, ExpParser.java и Exp.tokens.
Чтобы увидеть, все ли работает правильно, создайте этот тестовый класс:
import org.antlr.runtime.*;
public class ANTLRDemo {
public static void main(String[] args) throws Exception {
ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
ExpLexer lexer = new ExpLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
ExpParser parser = new ExpParser(tokens);
parser.eval();
}
}
и скомпилируйте это:
// *nix/MacOS
javac -cp .:antlr-3.2.jar ANTLRDemo.java
// Windows
javac -cp .;antlr-3.2.jar ANTLRDemo.java
и затем запустите его:
// *nix/MacOS
java -cp .:antlr-3.2.jar ANTLRDemo
// Windows
java -cp .;antlr-3.2.jar ANTLRDemo
Если все идет хорошо, ничего не выводится на консоль. Это означает, что парсер не нашел никакой ошибки. Когда вы меняете "12*(5-6)" на "12*(5-6" а затем перекомпилируете и запускаете его, должно быть напечатано следующее:
line 0:-1 mismatched input '<EOF>' expecting ')'
Хорошо, теперь мы хотим добавить немного кода Java в грамматику, чтобы синтаксический анализатор действительно делал что-то полезное. Добавление кода может быть сделано путем размещения { и } внутри вашей грамматики с некоторым простым Java-кодом внутри.
Но сначала: все правила синтаксического анализатора в файле грамматики должны возвращать примитивное двойное значение. Вы можете сделать это, добавив returns [double value] после каждого правила:
grammar Exp;
eval returns [double value]
: additionExp
;
additionExp returns [double value]
: multiplyExp
( '+' multiplyExp
| '-' multiplyExp
)*
;
// ...
который требует небольшого объяснения: каждое правило должно возвращать двойное значение. Теперь, чтобы "взаимодействовать" с double value возвращаемого значения (которое НЕ находится внутри простого блока кода Java {...}) внутри блока кода, вам необходимо добавить знак доллара перед value:
grammar Exp;
/* This will be the entry point of our parser. */
eval returns [double value]
: additionExp { /* plain code block! */ System.out.println("value equals: "+$value); }
;
// ...
Здесь грамматика, но теперь с добавленным кодом Java:
grammar Exp;
eval returns [double value]
: exp=additionExp {$value = $exp.value;}
;
additionExp returns [double value]
: m1=multiplyExp {$value = $m1.value;}
( '+' m2=multiplyExp {$value += $m2.value;}
| '-' m2=multiplyExp {$value -= $m2.value;}
)*
;
multiplyExp returns [double value]
: a1=atomExp {$value = $a1.value;}
( '*' a2=atomExp {$value *= $a2.value;}
| '/' a2=atomExp {$value /= $a2.value;}
)*
;
atomExp returns [double value]
: n=Number {$value = Double.parseDouble($n.text);}
| '(' exp=additionExp ')' {$value = $exp.value;}
;
Number
: ('0'..'9')+ ('.' ('0'..'9')+)?
;
WS
: (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
;
и поскольку наше правило eval теперь возвращает значение double, измените ваш ANTLRDemo.java на это:
import org.antlr.runtime.*;
public class ANTLRDemo {
public static void main(String[] args) throws Exception {
ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
ExpLexer lexer = new ExpLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
ExpParser parser = new ExpParser(tokens);
System.out.println(parser.eval()); // print the value
}
}
Снова (заново) сгенерируйте новый лексер и парсер из вашей грамматики (1), скомпилируйте все классы (2) и запустите ANTLRDemo (3):
// *nix/MacOS
java -cp antlr-3.2.jar org.antlr.Tool Exp.g // 1
javac -cp .:antlr-3.2.jar ANTLRDemo.java // 2
java -cp .:antlr-3.2.jar ANTLRDemo // 3
// Windows
java -cp antlr-3.2.jar org.antlr.Tool Exp.g // 1
javac -cp .;antlr-3.2.jar ANTLRDemo.java // 2
java -cp .;antlr-3.2.jar ANTLRDemo // 3
и теперь вы увидите результат выражения 12*(5-6) напечатанный на вашей консоли!
Опять же: это очень краткое объяснение. Я призываю вас просмотреть вики ANTLR и прочитать некоторые учебные пособия и/или поиграть с тем, что я только что опубликовал.
Удачи!
РЕДАКТИРОВАТЬ:
В этом посте показано, как расширить приведенный выше пример, чтобы можно было предоставить Map<String, Double>, которая содержит переменные в предоставленном выражении.
Чтобы этот код работал с текущей версией Antlr (июнь 2014 г.), мне нужно было внести несколько изменений. ANTLRStringStream должен был стать ANTLRInputStream, возвращаемое значение необходимо изменить с parser.eval() на parser.eval().value, и мне нужно было удалить предложение WS в конце, потому что значения атрибутов, такие как $channel, больше не разрешены появляться в действиях лексера.
Я только что разместил первые части видеоурока по ANTLR. См
http://javadude.com/articles/antlr3xtut
Надеюсь, вам понравится!
Мега-учебник ANTLR Габриэле Томассетти очень полезен
Здесь есть примеры грамматики, примеры посетителей на разных языках (Java, JavaScript, С# и Python) и многое другое. Настоятельно рекомендуется.
РЕДАКТИРОВАТЬ: другие полезные статьи Габриэле Томассетти на ANTLR
Для Antlr 4 процесс генерации кода java находится ниже: -
java -cp antlr-4.5.3-complete.jar org.antlr.v4.Tool Exp.g
Обновите свое имя jar в пути к классам соответственно.
В https://github.com/BITPlan/com.bitplan.antlr вы найдете Java-библиотеку ANTLR с некоторыми полезными вспомогательными классами и несколькими полными примерами. Он готов к использованию с maven и если вам нравится eclipse и maven.
https://github.com/BITPlan/com.bitplan.antlr/blob/master/src/main/antlr4/com/bitplan/exp/Exp.g4
- это простой язык выражения, который может выполнять умножение и добавление операций. https://github.com/BITPlan/com.bitplan.antlr/blob/master/src/test/java/com/bitplan/antlr/TestExpParser.java имеет соответствующие модульные тесты для него.
https://github.com/BITPlan/com.bitplan.antlr/blob/master/src/main/antlr4/com/bitplan/iri/IRIParser.g4 - это анализатор IRI, который был разделен на три части:
https://github.com/BITPlan/com.bitplan.antlr/blob/master/src/test/java/com/bitplan/antlr/TestIRIParser.java имеет модульные тесты для него.
Лично я нашел эту самую сложную часть, чтобы получить право. См. http://wiki.bitplan.com/index.php/ANTLR_maven_plugin
https://github.com/BITPlan/com.bitplan.antlr/tree/master/src/main/antlr4/com/bitplan/expr
содержит еще три примера, которые были созданы для проблемы производительности ANTLR4 в более ранней версии. Тем временем эти проблемы были исправлены, как показывает тестовый файл https://github.com/BITPlan/com.bitplan.antlr/blob/master/src/test/java/com/bitplan/antlr/TestIssue994.java.
версия 4.7.1 была немного другой: для импорта:
import org.antlr.v4.runtime.*;
для основного сегмента - обратите внимание на CharStreams:
CharStream in = CharStreams.fromString("12*(5-6)");
ExpLexer lexer = new ExpLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
ExpParser parser = new ExpParser(tokens);