Как добавить библиотеки Boost в CMakeLists.txt?

Ответ 1

Поместите это в свой CMakeLists.txt файл (измените любые параметры с OFF на ON, если хотите):

set(Boost_USE_STATIC_LIBS OFF) 
set(Boost_USE_MULTITHREADED ON)  
set(Boost_USE_STATIC_RUNTIME OFF) 
find_package(Boost 1.45.0 COMPONENTS *boost libraries here*) 

if(Boost_FOUND)
    include_directories(${Boost_INCLUDE_DIRS}) 
    add_executable(progname file1.cxx file2.cxx) 
    target_link_libraries(progname ${Boost_LIBRARIES})
endif()

Очевидно, вам нужно поместить нужные библиотеки, где я положил *boost libraries here*. Например, если вы используете библиотеку filesystem и regex, которую вы должны написать:

find_package(Boost 1.45.0 COMPONENTS filesystem regex)

Ответ 2

Вы можете использовать find_package для поиска доступных библиотек повышения. Он отклоняет поиск Boost до FindBoost.cmake, который по умолчанию установлен с CMake.

При поиске Boost вызов find_package() заполнит множество переменных (проверьте ссылку FindBoost.cmake). Среди них BOOST_INCLUDE_DIRS, Boost_LIBRARIES и Boost_XXX_LIBRARY переменные, с заменой XXX на конкретные библиотеки Boost. Вы можете использовать их для указания include_directories и target_link_libraries.

Например, предположим, что вам понадобится boost:: program_options и boost:: regex, вы бы сделали что-то вроде:

find_package( Boost REQUIRED COMPONENTS program_options regex )
include_directories( ${Boost_INCLUDE_DIRS} )
add_executable( run main.cpp ) # Example application based on main.cpp

# Alternatively you could use ${Boost_LIBRARIES} here.
target_link_libraries( run ${Boost_PROGRAM_OPTIONS_LIBRARY} ${Boost_REGEX_LIBRARY} )

Некоторые общие советы:

• При поиске FindBoost проверяет переменную окружения $ENV {BOOST_ROOT}. Вы можете установить эту переменную перед вызовом find_package, если это необходимо.
• Когда у вас есть несколько версий сборки boost (multi-threaded, static, shared и т.д.), вы можете указать желаемую конфигурацию перед вызовом find_package. Сделайте это, установив некоторые из следующих переменных в On: Boost_USE_STATIC_LIBS, Boost_USE_MULTITHREADED, Boost_USE_STATIC_RUNTIME
• При поиске Boost в Windows позаботьтесь о автоматической привязке. Прочтите "ПРИМЕЧАНИЕ для пользователей Visual Studio" в ссылка.
  • Мой совет - отключить автоматическую привязку и использовать обработку зависимостей cmake: add_definitions( -DBOOST_ALL_NO_LIB )
  • В некоторых случаях вам может потребоваться явно указать, что используется динамическое Boost: add_definitions( -DBOOST_ALL_DYN_LINK )

Ответ 3

Адаптация ответа @LainIwakura для современного синтаксиса CMake с импортированными целями:

set(Boost_USE_STATIC_LIBS OFF) 
set(Boost_USE_MULTITHREADED ON)  
set(Boost_USE_STATIC_RUNTIME OFF) 
find_package(Boost 1.45.0 COMPONENTS filesystem regex) 

if(Boost_FOUND)
    add_executable(progname file1.cxx file2.cxx) 
    target_link_libraries(progname Boost::filesystem Boost::regex)
endif()

Обратите внимание: теперь нет необходимости указывать каталоги include вручную, так как он уже позаботился о импортированных целях Boost::filesystem и Boost::regex.
regex и filesystem могут быть заменены любыми дополнительными библиотеками, которые вам нужны.

Ответ 4

Пусть это может быть полезным для некоторых людей. У меня произошла непослушная ошибка: неопределенная ссылка на символ "_ZN5boost6system15system_categoryEv"//usr/lib/x86_64-linux-gnu/libboost_system.so.1.58.0: ошибка при добавлении символов: DSO отсутствует в командной строке и почему-то мне не хватало явно включить библиотеки "system" и "filesystem". Итак, я написал эти строки в CMakeLists.txt

Эти строки пишутся в начале до создания исполняемого файла проекта, так как на этом этапе нам не нужно связывать библиотеку boost с нашим исполняемым файлом проекта.

set(Boost_USE_STATIC_LIBS OFF) 
set(Boost_USE_MULTITHREADED ON)  
set(Boost_USE_STATIC_RUNTIME OFF) 
set(Boost_NO_SYSTEM_PATHS TRUE) 

if (Boost_NO_SYSTEM_PATHS)
  set(BOOST_ROOT "${CMAKE_CURRENT_SOURCE_DIR}/../../3p/boost")
  set(BOOST_INCLUDE_DIRS "${BOOST_ROOT}/include")
  set(BOOST_LIBRARY_DIRS "${BOOST_ROOT}/lib")
endif (Boost_NO_SYSTEM_PATHS)


find_package(Boost COMPONENTS regex date_time system filesystem thread graph program_options) 

find_package(Boost REQUIRED regex date_time system filesystem thread graph program_options)
find_package(Boost COMPONENTS program_options REQUIRED)

Теперь в конце файла я написал эти строки, рассматривая "KeyPointEvaluation" как исполняемый файл моего проекта.

if(Boost_FOUND)
    include_directories(${BOOST_INCLUDE_DIRS})
    link_directories(${Boost_LIBRARY_DIRS})
    add_definitions(${Boost_DEFINITIONS})

    include_directories(${Boost_INCLUDE_DIRS})  
    target_link_libraries(KeyPointEvaluation ${Boost_LIBRARIES})
    target_link_libraries( KeyPointEvaluation ${Boost_PROGRAM_OPTIONS_LIBRARY} ${Boost_FILESYSTEM_LIBRARY} ${Boost_REGEX_LIBRARY} ${Boost_SYSTEM_LIBRARY})
endif()

Ответ 5

Я согласен с ответами 1 и 2. Однако я предпочитаю отдельно указывать каждую библиотеку. Это упрощает работу приложений в крупных проектах. Тем не менее, существует опасность ошибочного ввода имен переменных (чувствительных к регистру). В этом случае нет прямой ошибки cmake, но некоторые проблемы с компоновщиками ссылок undefined позже, что может занять некоторое время. Поэтому я использую следующую функцию cmake:

function(VerifyVarDefined)
  foreach(lib ${ARGV}) 
    if(DEFINED ${lib})
    else(DEFINED ${lib})
      message(SEND_ERROR "Variable ${lib} is not defined")
    endif(DEFINED ${lib})
  endforeach()
endfunction(VerifyVarDefined)

В приведенном выше примере это выглядит так:

VerifyVarDefined(Boost_PROGRAM_OPTIONS_LIBRARY Boost_REGEX_LIBRARY)
target_link_libraries( run ${Boost_PROGRAM_OPTIONS_LIBRARY} ${Boost_REGEX_LIBRARY} )

Если бы я написал "BOOST_PROGRAM_OPTIONS_LIBRARY", была бы ошибка, вызванная cmake и не намного позже срабатывающая компоновщиком.

Ответ 6

Попробуйте как сказать Boost документации:

set(Boost_USE_STATIC_LIBS        ON)  # only find static libs
set(Boost_USE_DEBUG_LIBS         OFF) # ignore debug libs and 
set(Boost_USE_RELEASE_LIBS       ON)  # only find release libs 
set(Boost_USE_MULTITHREADED      ON)
set(Boost_USE_STATIC_RUNTIME    OFF) 
find_package(Boost 1.66.0 COMPONENTS date_time filesystem system ...)
if(Boost_FOUND)   
    include_directories(${Boost_INCLUDE_DIRS})
    add_executable(foo foo.cc)   
    target_link_libraries(foo ${Boost_LIBRARIES})
endif()

Не забудьте заменить foo на имя вашего проекта и компоненты на ваш!