Подтвердить что ты не робот

Как преобразовать std::string в NSString?

Привет, Я пытаюсь преобразовать стандартный std::string в NSString, но мне не повезло.

Я могу успешно конвертировать с NSString в std::string со следующим кодом

NSString *realm = @"Hollywood";
std::string REALM = [realm cStringUsingEncoding:[NSString defaultCStringEncoding]];

Однако я получаю ошибку времени компиляции, когда я пытаюсь выполнить следующие

NSString *errorMessage = [NSString stringWithCString:REALM encoding:[NSString defaultCStringEncoding]];

Ошибка, которую я получаю,

Cannot convert 'std::string' to 'const char*' in argument passing

Я что-то пропустил?

Спасибо заранее.

Ответ 1

Получить c-строку из std::string для преобразования:

NSString *errorMessage = [NSString stringWithCString:REALM.c_str() 
                                   encoding:[NSString defaultCStringEncoding]];

Ответ 2

Во-первых, вы должны использовать Objective-C ++ для этого, чтобы работать в малейшей степени; самый простой способ обеспечить переименование всех ваших файлов *.m на *.mm

На сегодняшний день наиболее удобный (не устаревший) ручной способ получения С++ std::string в NSString:

std::string param; // <-- input
NSString* result = [NSString stringWithUTF8String:param.c_str()];
NSString* alternative = [[NSString alloc] initWithUTF8String:param.c_str()];

Это будет работать в большинстве случаев - и если вы не будете делать определенное обнаружение и преобразование кодировки, UTF-8 даст вам хороший результат для того, чтобы не латинские символы "просто работали".

Если вы создаете более крупное приложение или работаете не только с ним, вы, вероятно, захотите что-то более удобное.

Адаптировано из cocoa -dev архивы списков рассылки

@interface NSString (cppstring_additions)
+(NSString*) stringWithwstring:(const std::wstring&)string;
+(NSString*) stringWithstring:(const std::string&)string;
-(std::wstring) getwstring;
-(std::string) getstring;
@end

@implementation NSString (cppstring_additions)

#if TARGET_RT_BIG_ENDIAN
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32BE);
#else
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32LE);
#endif

+(NSString*) stringWithwstring:(const std::wstring&)ws
{
    char* data = (char*)ws.data();
    unsigned size = ws.size() * sizeof(wchar_t);

    NSString* result = [[NSString alloc] initWithBytes:data length:size encoding:kEncoding_wchar_t];
    return result;
}
+(NSString*) stringWithstring:(const std::string&)s
{
    NSString* result = [[NSString alloc] initWithUTF8String:s.c_str()];
    return result;
}

-(std::wstring) getwstring
{
    NSData* asData = [self dataUsingEncoding:kEncoding_wchar_t];
    return std::wstring((wchar_t*)[asData bytes], [asData length] / sizeof(wchar_t));
}
-(std::string) getstring
{
    return [self UTF8String];
}

@end

С этим на месте (и соответственно #import ed) вы можете теперь:

NSString* result = [NSString stringWithstring:param];
string convertedBack = [result getstring];

И то же самое для std::wstring, что более чем удобно.

Ответ 3

NSString* mystring = [NSString stringWithUTF8String:stdstring.c_str()];

Ответ 4

У Apple теперь есть новый способ, которым они хотят, чтобы вы сделали это преобразование. В XCode7 я использовал параметр Edit > Convert > To Modern Objective C Syntax..., чтобы узнать это. Он использует сокращенный символ @.

std::string sCPPString = "Hello World!";
NSString *sAppleString = @(sCPPString.c_str());

Ответ 5

Я также обнаружил, что:

NSString *nsString = [NSString stringWithFormat:@"%s",standardString];

Работает как чемпион.

Ответ 6

Вот фрагмент кода/пример:

string str_simple = "HELLO WORLD";

//string to NSString
NSString *stringinObjC = [NSString stringWithCString:str_simple.c_str()
                                encoding:[NSString defaultCStringEncoding]];            
NSLog(stringinObjC);