Командная строка Windows для чтения первой строки из текстового файла

Ответ 1

Здесь командный файл общего назначения для печати верхних n строк из файла, такого как утилита GNU head, а не только для одной строки.

@echo off

if [%1] == [] goto usage
if [%2] == [] goto usage

call :print_head %1 %2
goto :eof

REM
REM print_head
REM Prints the first non-blank %1 lines in the file %2.
REM
:print_head
setlocal EnableDelayedExpansion
set /a counter=0

for /f ^"usebackq^ eol^=^

^ delims^=^" %%a in (%2) do (
        if "!counter!"=="%1" goto :eof
        echo %%a
        set /a counter+=1
)

goto :eof

:usage
echo Usage: head.bat COUNT FILENAME

Например:

Z:\>head 1 "test file.c"
; this is line 1

Z:\>head 3 "test file.c"
; this is line 1
    this is line 2
line 3 right here

В настоящее время он не подсчитывает пустые строки. Он также зависит от ограничения длины строки в пакетном файле размером 8 КБ.

Ответ 2

ээ? imo это намного проще

  set /p texte=< file.txt  
  echo %texte%

Ответ 3

Вы, ребята,...

C:\>findstr /n . c:\boot.ini | findstr ^1:

1:[boot loader]

C:\>findstr /n . c:\boot.ini | findstr ^3:

3:default=multi(0)disk(0)rdisk(0)partition(1)\WINNT

C:\>

Ответ 4

Вы можете попробовать:

@echo off

for /f %%a in (sample.txt) do (
  echo %%a
  exit /b
)

изменить Или, скажем, у вас есть четыре столбца данных и хотите от 5-й строки вниз, попробуйте следующее:

@echo off

for /f "skip=4 tokens=1-4" %%a in (junkl.txt) do (
  echo %%a %%b %%c %%d
)

Ответ 5

Спасибо thetalkingwalnut с ответом Командная строка Windows для чтения первой строки из текстового файла Я придумал следующее решение:

@echo off
for /f "delims=" %%a in ('type sample.txt') do (
echo %%a
exit /b
)

Ответ 6

Слегка опираясь на ответы других людей. Теперь вы можете указать файл, который хотите прочитать, и переменную, в которую вы хотите внести результат:

@echo off
for /f "delims=" %%x in (%2) do (
set %1=%%x
exit /b
)

Это означает, что вы можете использовать вышеприведенное (если вы назвали его getline.bat)

c:\> dir > test-file
c:\> getline variable test-file
c:\> set variable  
variable= Volume in drive C has no label.

Ответ 7

Один вкладыш, полезный для перенаправления stdout с помощью " > ":

@for /f %%i in ('type yourfile.txt') do @echo %%i & exit

Ответ 8

Проблема с решениями EXIT/B, когда более реалистично внутри пакетного файла, как только одна его часть, является следующей. После EXIT/B последующая обработка в указанном пакетном файле отсутствует. Обычно для партий гораздо больше, чем просто одна, ограниченная задача.

Чтобы противостоять этой проблеме:

@echo off & setlocal enableextensions enabledelayedexpansion
set myfile_=C:\_D\TEST\My test file.txt
set FirstLine=
for /f "delims=" %%i in ('type "%myfile_%"') do (
  if not defined FirstLine set FirstLine=%%i)
echo FirstLine=%FirstLine%
endlocal & goto :EOF

(Тем не менее, так называемые ядовитые персонажи по-прежнему будут проблемой.)

Подробнее о том, как получить определенную строку с командами партии:

Как получить n-й, первый и последний строки текстового файла? " Http://www.netikka.net/tsneti/info/tscmd023.htm

[Добавлено 28 августа 2012] Можно также иметь:

@echo off & setlocal enableextensions
set myfile_=C:\_D\TEST\My test file.txt
for /f "tokens=* delims=" %%a in (
  'type "%myfile_%"') do (
    set FirstLine=%%a& goto _ExitForLoop)
:_ExitForLoop
echo FirstLine=%FirstLine%
endlocal & goto :EOF

Ответ 9

Попробуйте это

@echo off
setlocal enableextensions enabledelayedexpansion
set firstLine=1
for /f "delims=" %%i in (yourfilename.txt) do (
    if !firstLine!==1 echo %%i
    set firstLine=0
)
endlocal

Ответ 10

Примечание. Подход пакетного файла будет ограничен линией для командного процессора DOS - см. Каков предел длины командной строки?.

Поэтому, если вы пытаетесь обработать файл с любыми строками, более 8192, символы script просто пропустят их, поскольку это значение не может быть сохранено.

Ответ 11

Другой путь

setlocal enabledelayedexpansion
@echo off
for /f "delims=" %%i in (filename.txt) do (
if 1==1 (
set first_line=%%i
echo !first_line!
goto :eof
))

Ответ 12

Вот обходной путь с использованием powershell:

powershell (Get-Content file.txt)[0]

(Вы также можете легко прочитать ряд строк с powershell (Get-Content file.txt)[0..3])

Если вам нужно установить переменную внутри пакетного скрипта в качестве первой строки file.txt вы можете использовать:

for /f "usebackq delims=" %%a in ('powershell ^(Get-Content file.txt^)[0]') do (set "head=%%a")

Ответ 13

Чтобы создать файл (file1.txt, file1[1].txt, file1[2].txt и т.д.):

START/WAIT C:\LAERCIO\DELPHI\CICLADOR\dprCiclador.exe C:\LAERCIUM\Ciclavel.txt

rem set/p ciclo=< C:\LAERCIUM\Ciclavel.txt:
set/p ciclo=< C:\LAERCIUM\Ciclavel.txt

rem echo %ciclo%:
echo %ciclo%

И это работает.

Ответ 14

Я вижу некоторые ответы на циклы, но не такие простые, как:

for /f "tokens=1 delims=" %%G in (sample.txt) do (echo %%G);

• delims=, кажется, настроил его так, чтобы каждая полная строка анализировалась как токен.
• tokens=1 читает только первый токен, таким образом избегая необходимости в exit, goto или создании любой переменной итератора.

Конечно, используйте опцию пропуска или другой разделитель, если это необходимо для вашего файла.