Может ли командный файл Windows определять собственное имя файла?

Ответ 1

Да.

Используйте специальную переменную %0, чтобы получить путь к текущему файлу.

Напишите %~n0, чтобы получить только имя файла без расширения.

Напишите %~n0%~x0, чтобы получить имя файла и расширение.

Ответ 2

Используя следующий script, основанный на ответе SLaks, я решил, что правильный ответ:

echo The name of this file is: %~n0%~x0
echo The name of this file is: %~nx0

И вот мой тест script:

@echo off
echo %0
echo %~0
echo %n0
echo %x0
echo %~n0
echo %dp0
echo %~dp0
pause

Интересно, что % nx0 не будет работать, поскольку мы знаем, что '~' char обычно используется для того, чтобы вырезать/урезать цитаты из переменной.

Ответ 3

Вы можете получить имя файла, но вы также можете получить полный путь, в зависимости от того, что вы размещаете между "% ~" и "0". Сделайте выбор из

d -- drive
p -- path
n -- file name
x -- extension
f -- full path

Например, изнутри c:\tmp\foo.bat, %~nx0 дает вам "foo.bat", а %~dpnx0 дает "c:\tmp\foo.bat". Обратите внимание, что части всегда собраны в каноническом порядке, поэтому, если вы получите симпатичный и попробуйте %~xnpd0, вы еще получите "c:\tmp\foo.bat"

Ответ 4

Имейте в виду, что 0 - частный случай номеров параметров внутри командного файла, где 0 означает этот файл, как указано в командной строке.

Итак, если файл myfile.bat, вы можете назвать его несколькими способами следующим образом, каждый из которых даст вам другой результат использования% 0 или% ~ 0:

MyFile

myfile.bat

MYDIR\myfile.bat

C:\MYDIR\myfile.bat

"C:\MYDIR\myfile.bat"

Все вышесказанное является юридическим вызовом, если вы вызываете его из правильного относительного места в каталог, в котором он существует. % ~ 0 разбивает кавычки из последнего примера, тогда как% 0 не делает.

Поскольку все они дают разные результаты,% 0 и% ~ 0 вряд ли будут тем, что вы на самом деле хотите использовать.

Здесь приведен командный файл для иллюстрации:

@echo Full path and filename: %~f0
@echo Drive: %~d0
@echo Path: %~p0
@echo Drive and path: %~dp0
@echo Filename without extension: %~n0
@echo Filename with    extension: %~nx0
@echo Extension: %~x0
@echo Filename as given on command line: %0
@echo Filename as given on command line minus quotes: %~0
@REM Build from parts
@SETLOCAL
@SET drv=%~d0
@SET pth=%~p0
@SET fpath=%~dp0
@SET fname=%~n0
@SET ext=%~x0
@echo Simply Constructed name: %fpath%%fname%%ext%
@echo Fully  Constructed name: %drv%%pth%%fname%%ext%
@ENDLOCAL
pause

Ответ 5

%0 - это то, что вы ищете. Подробнее см. этот вопрос.

echo %0

Ответ 6

Попробуйте выполнить пример ниже, чтобы почувствовать, как работают магические переменные.

@echo off

SETLOCAL EnableDelayedExpansion

echo Full path and filename: %~f0
echo Drive: %~d0
echo Path: %~p0
echo Drive and path: %~dp0
echo Filename without extension: %~n0
echo Filename with    extension: %~nx0
echo Extension: %~x0

echo date time : %~t0
echo file size: %~z0

ENDLOCAL

Соответствующие правила следующие.

%~I         - expands %I removing any surrounding quotes ("")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string