Итак, у меня этот запрос работает (где signal_data является столбцом) в Sybase, но он не работает в Microsoft SQL Server:
HEXTOINT(SUBSTRING((INTTOHEX(signal_data)),5,2)) as Signal
Я также использую его в Excel (где A1 содержит значение):
=HEX2DEC(LEFT(DEC2HEX(A1),LEN(DEC2HEX(A1))-2))
Кто-нибудь знает, как я буду делать это в SQL Server?
Конвертировать INT в гекс:
SELECT CONVERT(VARBINARY(8), 16777215)
Преобразовать гекс в INT:
SELECT CONVERT(INT, 0xFFFFFF)
В приведенном выше примере есть ограничение, что он работает только тогда, когда значение HEX задано как целочисленный литерал. Для полноты, если значение для преобразования представляет собой шестнадцатеричную строку (например, найденную в столбце varchar), используйте:
-- If the '0x' marker is present:
SELECT CONVERT(INT, CONVERT(VARBINARY, '0x1FFFFF', 1))
-- If the '0x' marker is NOT present:
SELECT CONVERT(INT, CONVERT(VARBINARY, '1FFFFF', 2))
Примечание. Строка должна содержать четное число шестнадцатеричных цифр. Нечетное количество цифр приведет к ошибке.
Более подробную информацию можно найти в разделе "Бинарные стили" в CAST и CONVERT (Transact-SQL). Я считаю, что требуется SQL Server 2008 или более поздняя версия.
Собственно, встроенная функция называется master.dbo.fn_varbintohexstr.
Итак, например:
SELECT 100, master.dbo.fn_varbintohexstr(100)
Дает вам
100 0x00000064
эквиваленты SQL Server для строковых DEC2HEX в Excel, функции HEX2DEC:
--Convert INT to hex string:
PRINT CONVERT(VARCHAR(8),CONVERT(VARBINARY(4), 16777215),2) --DEC2HEX
--Convert hex string to INT:
PRINT CONVERT(INT,CONVERT(VARBINARY(4),'00FFFFFF',2)) --HEX2DEC
Преобразовать int в hex:
SELECT FORMAT(512+255,'X')
Это возможно с помощью функции FORMAT, доступной на SQL Server 2012 и выше
select FORMAT(10,'x2')
Результаты в:
0a
Вот функция SQL-сервера, которая преобразует целочисленное значение в шестнадцатеричное представление как varchar. Легко адаптироваться к другим типам баз данных
Например:
SELECT dbo.ToHex(4095) --> FFF
SQL:
CREATE FUNCTION ToHex(@value int)
RETURNS varchar(50)
AS
BEGIN
DECLARE @seq char(16)
DECLARE @result varchar(50)
DECLARE @digit char(1)
SET @seq = '0123456789ABCDEF'
SET @result = SUBSTRING(@seq, (@value%16)+1, 1)
WHILE @value > 0
BEGIN
SET @digit = SUBSTRING(@seq, ((@value/16)%16)+1, 1)
SET @value = @value/16
IF @value <> 0 SET @result = @digit + @result
END
RETURN @result
END
GO
Традиционный 4-битный гексагон довольно прямой. Hex String to Integer (Предполагаемое значение сохраняется в поле FHexString):
CONVERT(BIGINT,CONVERT(varbinary(4),
(SELECT master.dbo.fn_cdc_hexstrtobin(
LEFT(FMEID_ESN,8)
))
))
Целое число с шестнадцатеричной строкой (Предполагая, что значение хранится в поле FInteger):
(SELECT master.dbo.fn_varbintohexstr(CONVERT(varbinary,CONVERT(int,
FInteger
))))
Важно отметить, что когда вы начинаете использовать размеры битов, которые вызывают обмен реестром, особенно на компьютере с Intel, ваши High и Low и Left и Rights в регистрах будут меняться местами из-за малозначительного характера Intel. Например, при использовании varbinary (3) мы говорим о шестисимвольном Hex. В этом случае ваши биты соединяются как следующие индексы справа налево "54,32,10". В системе intel вы ожидаете "76,54,32,10". Поскольку вы используете только 6 из 8, вам нужно помнить о том, чтобы делать свопы самостоятельно. "76,54" будет квалифицироваться как ваш левый, а "32,10" будет квалифицироваться как ваше право. Запятая разделяет ваше высоко и низко. Intel меняет максимумы и минимумы, затем левые и права. Итак, чтобы сделать преобразование... вздох, вам нужно поменять их себе, например, следующее преобразует первые 6 из шести символов:
(SELECT master.dbo.fn_replvarbintoint(
CONVERT(varbinary(3),(SELECT master.dbo.fn_cdc_hexstrtobin(
--intel processors, registers are switched, so reverse them
----second half
RIGHT(FHex8,2)+ --0,1 (0 indexed)
LEFT(RIGHT(FHex8,4),2)+ -- 2,3 (oindex)
--first half
LEFT(RIGHT(FHex8,6),2) --4,5
)))
))
Это немного сложно, поэтому я бы постарался сохранить мои преобразования в шестнадцатеричном символе (varbinary (4)).
Таким образом, это должно ответить на ваш вопрос. Обширное.
Используйте master.dbo.fnbintohexstr(16777215) для преобразования в представление varchar.
Declare @Dato xml
Set @Dato = Convert(xml, '<dato>FF</dato>')
Select Cast( rw.value( 'xs:hexBinary( text()[1])' , 'varbinary(max)' ) as int ) From @Dato.nodes('dato') as T(rw)
Ответ Максима Козленко хорош и может быть слегка изменен для обработки кодирования числового значения в любом формате кода. Например:
CREATE FUNCTION [dbo].[IntToAlpha](@Value int)
RETURNS varchar(30)
AS
BEGIN
DECLARE @CodeChars varchar(100)
SET @CodeChars = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'
DECLARE @CodeLength int = 26
DECLARE @Result varchar(30) = ''
DECLARE @Digit char(1)
SET @Result = SUBSTRING(@CodeChars, (@Value % @CodeLength) + 1, 1)
WHILE @Value > 0
BEGIN
SET @Digit = SUBSTRING(@CodeChars, ((@Value / @CodeLength) % @CodeLength) + 1, 1)
SET @Value = @Value / @CodeLength
IF @Value <> 0 SET @Result = @Digit + @Result
END
RETURN @Result
END
Таким образом, большое количество, например, 150 миллионов, становится всего 6 символов (150 000 000 = "MQGJMU" )
Вы также можете использовать разные символы в разных последовательностях в качестве устройства шифрования. Или передайте символы кода и длину символов и используйте в качестве метода соления для шифрования.
И наоборот:
CREATE FUNCTION [dbo].[AlphaToInt](@Value varchar(7))
RETURNS int
AS
BEGIN
DECLARE @CodeChars varchar(100)
SET @CodeChars = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'
DECLARE @CodeLength int = 26
DECLARE @Digit char(1)
DECLARE @Result int = 0
DECLARE @DigitValue int
DECLARE @Index int = 0
DECLARE @Reverse varchar(7)
SET @Reverse = REVERSE(@Value)
WHILE @Index < LEN(@Value)
BEGIN
SET @Digit = SUBSTRING(@Reverse, @Index + 1, 1)
SET @DigitValue = (CHARINDEX(@Digit, @CodeChars) - 1) * POWER(@CodeLength, @Index)
SET @Result = @Result + @DigitValue
SET @Index = @Index + 1
END
RETURN @Result
Дано:
declare @hexStr varchar(16), @intVal int
IntToHexStr:
select @hexStr = convert(varbinary, @intVal, 1)
HexStrToInt:
declare
@query varchar(100),
@parameters varchar(50)
select
@query = 'select @result = convert(int,' + @hb + ')',
@parameters = '@result int output'
exec master.dbo.Sp_executesql @query, @parameters, @intVal output
IIF(Fields!HIGHLIGHT_COLOUR.Value="","#FFFFFF","#" & hex(Fields!HIGHLIGHT_COLOUR.Value) & StrDup(6-LEN(hex(Fields!HIGHLIGHT_COLOUR.Value)),"0"))
Работает для меня как выражение в цвете шрифта
Чтобы преобразовать шестнадцатеричные строки в INT, я использовал это в прошлом. Он может быть изменен, чтобы преобразовать любую базу в INT фактически (Octal, Binary, whatever)
Declare @Str varchar(200)
Set @str = 'F000BE1A'
Declare @ndx int
Set @ndx = Len(@str)
Declare @RunningTotal BigInt
Set @RunningTotal = 0
While @ndx > 0
Begin
Declare @Exponent BigInt
Set @Exponent = Len(@Str) - @ndx
Set @RunningTotal = @RunningTotal +
Power(16 * 1.0, @Exponent) *
Case Substring(@str, @ndx, 1)
When '0' then 0
When '1' then 1
When '2' then 2
When '3' then 3
When '4' then 4
When '5' then 5
When '6' then 6
When '7' then 7
When '8' then 8
When '9' then 9
When 'A' then 10
When 'B' then 11
When 'C' then 12
When 'D' then 13
When 'E' then 14
When 'F' then 15
End
Set @ndx = @ndx - 1
End
Print @RunningTotal
Ниже приведены две функции: dbo.HexToInt и dbo.IntToHex, я использую их для такого преобразования:
if OBJECT_ID('dbo.HexToInt') is not null
drop function dbo.HexToInt
GO
create function dbo.HexToInt (@chars varchar(max))
returns int
begin
declare @char varchar(1), @len int, @i int, @r int, @tmp int, @pow int
set @chars = RTRIM(LTRIM(@chars))
set @len = LEN(@chars)
set @i = 1
set @r = 0
while @i <= @len
begin
set @pow = @len - @i
set @char = SUBSTRING(@chars, @i, 1)
if @char = '0'
set @tmp = 0
else if @char = '1'
set @tmp = 1
else if @char = '2'
set @tmp = 2
else if @char = '3'
set @tmp = 3
else if @char = '4'
set @tmp = 4
else if @char = '5'
set @tmp = 5
else if @char = '6'
set @tmp = 6
else if @char = '7'
set @tmp = 7
else if @char = '8'
set @tmp = 8
else if @char = '9'
set @tmp = 9
else if @char = 'A'
set @tmp = 10
else if @char = 'B'
set @tmp = 11
else if @char = 'C'
set @tmp = 12
else if @char = 'D'
set @tmp = 13
else if @char = 'E'
set @tmp = 14
else if @char = 'F'
set @tmp = 15
set @r = @r + @tmp * POWER(16,@pow)
set @i = @i + 1
end
return @r
end
И второй:
if OBJECT_ID('dbo.IntToHex') is not null
drop function dbo.IntToHex
GO
create function dbo.IntToHex (@val int)
returns varchar(max)
begin
declare @r varchar(max), @tmp int, @v1 int, @v2 int, @char varchar(1)
set @tmp = @val
set @r = ''
while 1=1
begin
set @v1 = @tmp / 16
set @v2 = @tmp % 16
if @v2 = 0
set @char = '0'
else if @v2 = 1
set @char = '1'
else if @v2 = 2
set @char = '2'
else if @v2 = 3
set @char = '3'
else if @v2 = 4
set @char = '4'
else if @v2 = 5
set @char = '5'
else if @v2 = 6
set @char = '6'
else if @v2 = 7
set @char = '7'
else if @v2 = 8
set @char = '8'
else if @v2 = 9
set @char = '9'
else if @v2 = 10
set @char = 'A'
else if @v2 = 11
set @char = 'B'
else if @v2 = 12
set @char = 'C'
else if @v2 = 13
set @char = 'D'
else if @v2 = 14
set @char = 'E'
else if @v2 = 15
set @char = 'F'
set @tmp = @v1
set @r = @char + @r
if @tmp = 0
break
end
return @r
end
У вас нет стандартного способа (т.е. ANSI) для этого преобразования.
Все, что вы делаете, будет запатентованной функциональностью.
Я бы предложил переместить это преобразование в ваш код, а не в зависимости от базы данных.