Создание имени файла в качестве метки времени в пакетном задании

Ответ 1

CP source.log %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%.log

Но это зависит от языка. Я не уверен, что локализован %DATE% или зависит от формата, указанного для короткой даты в Windows.

Вот независимый от локали способ извлечь текущую дату из этого ответа, но это зависит от WMIC и FOR /F:

FOR /F %%A IN ('WMIC OS GET LocalDateTime ^| FINDSTR \.') DO @SET B=%%A
CP source.log %B:~0,4%-%B:~4,2%-%B:~6,2%.log

Ответ 2

Это сработало для меня и было безопасным решением для файлов:

C:\ set SAVESTAMP=%DATE:/=-%@%TIME::=-%
C:\ set SAVESTAMP=%SAVESTAMP: =%
C:\ set SAVESTAMP=%SAVESTAMP:,=.%.jpg
C:\ echo %SAVESTAMP%
11-04-2[email protected]

Первая команда принимает DATE и заменяет / на -, принимает TIME и заменяет : на - и объединяет их в формат DATE @TIME. Второй оператор set удаляет любые пробелы и добавляет расширение .jpg.

Приведенный выше код используется в небольшом script, который извлекает изображения с IP-камеры безопасности для дальнейшей обработки:

:while
set SAVESTAMP=%DATE:/=-%@%TIME::=-%
set SAVESTAMP=%SAVESTAMP: =%
set SAVESTAMP=%SAVESTAMP:,=.%.jpg
wget-1.10.2.exe --tries=0 -O %SAVESTAMP% http://admin:<password>@<ip address>:<port>/snapshot.cgi
timeout 1
GOTO while

Ответ 3

Для French Locale (Франция) ТОЛЬКО, будьте осторожны, потому что / отображается:

echo %DATE%
08/09/2013

Для нашей проблемы с файлом журнала, вот мое предложение для French Locale ONLY:

SETLOCAL
set LOGFILE_DATE=%DATE:~6,4%.%DATE:~3,2%.%DATE:~0,2%
set LOGFILE_TIME=%TIME:~0,2%.%TIME:~3,2%
set LOGFILE=log-%LOGFILE_DATE%-%LOGFILE_TIME%.txt
rem log-2014.05.19-22.18.txt
command > %LOGFILE%

Ответ 4

Это независимое от локали решение (копировать в файл с именем SetDateTimeComponents.cmd):

@echo off
REM This script taken from the following URL:
REM http://www.winnetmag.com/windowsscripting/article/articleid/9177/windowsscripting_9177.html

REM Create the date and time elements.
for /f "tokens=1-7 delims=:/-, " %%i in ('echo exit^|cmd /q /k"prompt $d $t"') do (
   for /f "tokens=2-4 delims=/-,() skip=1" %%a in ('echo.^|date') do (
      set dow=%%i
      set %%a=%%j
      set %%b=%%k
      set %%c=%%l
      set hh=%%m
      set min=%%n
      set ss=%%o
   )
)

REM Let see the result.
echo %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss%

Я поместил все мои .cmd-скрипты в одну и ту же папку (% SCRIPTROOT%); любой script, которому нужны значения даты/времени, вызовет SetDateTimeComponents.cmd, как в следующем примере:

setlocal

@echo Initializing...
set SCRIPTROOT=%~dp0
set ERRLOG=C:\Oopsies.err

:: Log start time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : Start === >> %ERRLOG%

:: Perform some long running action and log errors to ERRLOG.

:: Log end time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : End === >> %ERRLOG%

Как показывает пример, вы можете вызвать SetDateTimeComponents.cmd, когда вам нужно обновить значения даты/времени. Скрытие разбора времени script в нем собственный файл SetDateTompocents.cmd - хороший способ скрыть уродливые детали и, что еще более важно, избежать опечаток.

Ответ 5

Это гарантирует, что выход представляет собой двухзначное значение... вы можете переставить вывод по своему вкусу и тестированию, не комментируя раздел диагностики. Наслаждайтесь!

(Я многому занимался этим с других форумов...)

:: ------------------ Date and Time Modifier ------------------------

@echo off
setlocal

:: THIS CODE WILL DISPLAY A 2-DIGIT TIMESTAMP FOR USE IN APPENDING FILENAMES

:: CREATE VARIABLE %TIMESTAMP%

for /f "tokens=1-8 delims=.:/-, " %%i in ('echo exit^|cmd /q /k"prompt $D $T"') do (
   for /f "tokens=2-4 skip=1 delims=/-,()" %%a in ('echo.^|date') do (
set dow=%%i
set %%a=%%j
set %%b=%%k
set %%c=%%l
set hh=%%m
set min=%%n
set sec=%%o
set hsec=%%p
)
)

:: ensure that hour is always 2 digits

if %hh%==0 set hh=00
if %hh%==1 set hh=01
if %hh%==2 set hh=02
if %hh%==3 set hh=03
if %hh%==4 set hh=04
if %hh%==5 set hh=05
if %hh%==6 set hh=06
if %hh%==7 set hh=07
if %hh%==8 set hh=08
if %hh%==9 set hh=09


:: --------- TIME STAMP DIAGNOSTICS -------------------------

:: Un-comment these lines to test output

:: echo dayOfWeek = %dow%
:: echo year = %yy%
:: echo month = %mm%
:: echo day = %dd%
:: echo hour = %hh%
:: echo minute = %min%
:: echo second = %sec%
:: echo hundredthsSecond = %hsec%
:: echo.
:: echo Hello! 
:: echo Today is %dow%, %mm%/%dd%. 
:: echo.
:: echo. 
:: echo.
:: echo.
:: pause

:: --------- END TIME STAMP DIAGNOSTICS ----------------------

:: assign timeStamp:
:: Add the date and time parameters as necessary - " yy-mm-dd-dow-min-sec-hsec "

endlocal & set timeStamp=%yy%%mm%%dd%_%hh%-%min%-%sec%
echo %timeStamp%

Ответ 6

Я часто использую это и помещаю все в одну команду копирования. Следующие экземпляры example.txt как example_YYYYMMDD_HHMMSS.txt и, конечно, вы можете изменить его в соответствии с вашим предпочтительным форматом. Кавычки нужны только в том случае, если в файле спецификаций есть пробелы. Если вы хотите повторно использовать ту же самую дату/метку времени, вам нужно сохранить ее в переменной.

copy "{path}\example.txt" "{path}\_%date:~10,4%%date:~4,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.txt"

Ответ 7

Возможно, это может помочь:

echo off
@prompt set date=$d$_ set time=$t$h$h$h
echo some log >> %date% %time%.log
exit

или

echo off
set v=%date%.log
echo some log >> %v%

Ответ 8

Создайте файл с текущей датой в качестве имени файла (например, 2008-11-08.dat)

echo hello > %date%.dat    

С текущей датой, но без "-" (например, 20081108.dat)

echo hello > %date:-=%.dat   

Ответ 9

Я собрал небольшую программу C, чтобы распечатать текущую временную метку (безопасный для локали, никаких плохих символов...). Затем я использую команду FOR для сохранения результата в переменной среды:

:: Get the timestamp
for /f %%x in ('@timestamp') do set TIMESTAMP=%%x

:: Use it to generate a filename
for /r %%x in (.\processed\*) do move "%%~x" ".\archived\%%~nx-%TIMESTAMP%%%~xx"

Здесь ссылка:

https://github.com/HarryPehkonen/dos-timestamp

Ответ 10

Вы можете просто определить текущий локальный формат и получить дату в вашем формате, например:

::for 30.10.2016 dd.MM.yyyy
if %date:~2,1%==. set d=%date:~-4%%date:~3,2%%date:~,2%
::for 10/30/2016 MM/dd/yyyy
if %date:~2,1%==/ set d=%date:~-4%%date:~,2%%date:~3,2%
::for 2016-10-30 yyyy-MM-dd
if %date:~4,1%==- set d=%date:~,4%%date:~5,2%%date:~-2%
::variable %d% have now value: 2016103 (yyyyMMdd)
set t=%time::=%
set t=%t:,=%
::variable %t% have now time without delimiters
cp source.log %d%_%t%.log

Ответ 11

Я знаю, что это старый пост, но есть более простой ответ FAR (хотя, возможно, он работает только в более новых версиях Windows). Просто используйте параметр /t для команд DATE и TIME для отображения только даты или времени и не запрашивать его, например:

@echo off
echo Starting test batch file > testlog.txt
date /t >> testlog.txt
time /t >> testlog.txt

Ответ 12

1) Вы можете скачать GNU coreutils, который поставляется с датой GNU

2) вы можете использовать VBScript, что упрощает обработку дат в Windows:

Set objFS = CreateObject("Scripting.FileSystemObject")
strFolder = "c:\test"
Set objFolder = objFS.GetFolder(strFolder)
current = Now
mth = Month(current)
d = Day(current)
yr = Year(current)
If Len(mth) <2 Then
    mth="0"&mth
End If
If Len(d) < 2 Then
    d = "0"&d
End If
timestamp=yr & "-" & mth &"-"& d
For Each strFile In objFolder.Files
    strFileName = strFile.Name
    If InStr(strFileName,"file_name_here") > 0 Then
        BaseName = objFS.GetBaseName(strFileName)
        Extension = objFS.GetExtensionName(strFileName)
        NewName = BaseName & "-" & timestamp & "." & Extension
        strFile.Name = NewName
    End If
Next

Запустите script как:

c:\test> cscript /nologo myscript.vbs

Ответ 13

Я знаю, что эта ветка устарела, но я просто хочу добавить это здесь, потому что она очень помогла мне разобраться в этом и о ее чистом виде. Самое приятное в этом - вы можете положить его в цикл для пакетного файла, который всегда работает. Журнал регистрации сервера или что-то в этом роде. Это то, что я использую в любом случае. Надеюсь, это когда-нибудь поможет кому-нибудь.

@setlocal enableextensions enabledelayedexpansion
@echo off

call :timestamp freshtime freshdate
echo %freshdate% - %freshtime% - Some data >> "%freshdate - Somelog.log"

:timestamp
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set hour=0%hour:~1,1%
set min=%time:~3,2%
if "%min:~0,1%" == " " set min=0%min:~1,1%
set secs=%time:~6,2%
if "%secs:~0,1%" == " " set secs=0%secs:~1,1%
set FreshTime=%hour%:%min%:%secs%

set year=%date:~-4%
set month=%date:~4,2%
if "%month:~0,1%" == " " set month=0%month:~1,1%
set day=%date:~7,2%
if "%day:~0,1%" == " " set day=0%day:~1,1%
set FreshDate=%month%.%day%.%year%

Ответ 14

Это хорошо работает с (моим) немецким языком, должно быть возможно настроить его на ваши нужды...

forfiles /p *PATH* /m *filepattern* /c "cmd /c ren @file 
%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%[email protected]"

Ответ 15

Потому что идея разрыва %DATE% и %TIME% в сторону и слияние их вместе кажется хрупкой в ​​лучшем случае, здесь альтернатива, которая использует powerhell oneliner:

for /f %i in ('powershell -c "get-date -format yyyy-MM-dd--HH-mm-ss"') do @set DATETIME=%i
set LOGFILE=my-script-%DATETIME%.txt

Ссылка для get-date здесь, с опциями формата для стиля .NET и UNIX.