Как использовать шаблон поддиров QMake?

Я начинаю изучать Qt. Я перехожу из мира Visual Studio, и я ищу способ организовать свою структуру проекта с помощью QMake. Я нашел шаблон "subdirs", но мне это трудно понять.

Моя структура проекта выглядит следующим образом:

project_dir/
    main.cpp
    project.pro
    logic/
      logic.pro
      some logic files
    gui/
      gui.pro
      gui files

Мой project.pro выглядит следующим образом

TEMPLATE = subdirs
SUBDIRS = logic \
          gui
SOURCES += main.cpp

В файлах .pro для подкаталогов установлены соответствующие переменные SOURCES, HEADERS и RESOURCES.

Скажите, пожалуйста, какие TARGET, TEMPLATE и другие необходимые значения я должен установить в .pro файлах.

Кроме того, есть ли какой-то хороший учебник QMake, отличный от официального?

Ответ 1

В дополнение к комментарий к Troubadour, я хотел бы отметить, что цель SUBDIRS хороша только для указания подкаталогов. Поэтому ваша дополнительная строка

SOURCES += main.cpp

в файле project.pro неверен и, скорее всего, не сможет создать файл main.cpp, в худшем случае. В лучшем случае qmake откажется разбирать файл, поскольку в нем есть противоречивые спецификации.

Я использовал шаблон SUBDIRS несколько раз, и это хорошо, если вы можете создавать детали в более или менее независимых библиотеках, по-видимому, как и у вас с логикой и с разделителем gui. Вот один из способов сделать это:

project_dir/
-project.pro
-common.pri
-logic/
----logic.pro
----some logic files
-gui/
----gui.pro
----gui files
-build/
----build.pro
----main.cpp

project.pro:

TEMPLATE = subdirs
SUBDIRS = logic \
          gui

# build must be last:
CONFIG += ordered
SUBDIRS += build

common.pri:

#Includes common configuration for all subdirectory .pro files.
INCLUDEPATH += . ..
WARNINGS += -Wall

TEMPLATE = lib

# The following keeps the generated files at least somewhat separate 
# from the source files.
UI_DIR = uics
MOC_DIR = mocs
OBJECTS_DIR = objs

Логика/logic.pro:

# Check if the config file exists
! include( ../common.pri ) {
    error( "Couldn't find the common.pri file!" )
}

HEADERS += logic.h
SOURCES += logic.cpp

# By default, TARGET is the same as the directory, so it will make 
# liblogic.a (in linux).  Uncomment to override.
# TARGET = target

гуй/gui.pro:

! include( ../common.pri ) {
    error( "Couldn't find the common.pri file!" )
}

FORMS += gui.ui
HEADERS += gui.h
SOURCES += gui.cpp

# By default, TARGET is the same as the directory, so it will make 
# libgui.a (in linux).  Uncomment to override.
# TARGET = target

сборки/build.pro:

TEMPLATE = app

SOURCES += main.cpp

LIBS += -L../logic -L../gui -llogic -lgui

# Will build the final executable in the main project directory.
TARGET = ../project

Ответ 2

Вы используете subdirs, если логические и gui-папки фактически отображают какую-то цель, например. библиотеку, которая может быть построена независимо от чего-либо еще. Если это случай, то просто используйте

TEMPLATE = lib
TARGET = logic
CONFIG += dll

в logic.pro.

Если они не являются независимыми объектами, а являются только папками, которые существуют для организации исходных файлов, тогда вы можете просто использовать .pri файл в каждом из них и включить их в .pro, используя

include(logic/logic.pri)
include(gui/gui.pri)

Просто помните, что пути к файлам в файлах .pri относятся к файлу .pro, а не к .pri. BTW, использование файла .pri является необязательным, поскольку вы все равно можете перечислить файлы в этих папках непосредственно в файле .pro. Файл .pri просто делает его более аккуратным и помогает сохранить файл .pro короче.