Как создать и записать в txt файл с помощью VBA

У меня есть файл, который добавляется или изменяется вручную на основе входов. Поскольку большая часть содержимого повторяется в этом файле, меняются только шестнадцатеричные значения, я хочу сделать его сгенерированным инструментом.

Я хочу написать коды c, которые будут напечатаны в этом .txt файле.

Что такое команда для создания файла .txt с использованием VBA и как мне писать на него

Ответ 1

Используйте FSO для создания файла и записи на него.

Dim fso as Object
Set fso = CreateObject("Scripting.FileSystemObject")
Dim oFile as Object
Set oFile = FSO.CreateTextFile(strPath)
oFile.WriteLine "test" 
oFile.Close
Set fso = Nothing
Set oFile = Nothing

Смотрите документацию здесь:

Ответ 2

Open ThisWorkbook.Path & "\template.txt" For Output As #1
Print #1, strContent
Close #1

Дополнительная информация:

Документы Microsoft: Open выражение
Документы Microsoft: Print # выражение
Документы Microsoft: Close выражение
wellsr.com: VBA записать в текстовый файл с оператором Print
Служба поддержки: свойство Workbook.Path

Ответ 3

простой способ с избыточным резервированием.

    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")

    Dim Fileout As Object
    Set Fileout = fso.CreateTextFile("C:\your_path\vba.txt", True, True)
    Fileout.Write "your string goes here"
    Fileout.Close

Ответ 4

Чтобы уточнить Бен ответ:

Если вы добавите ссылку на Microsoft Scripting Runtime и правильно введете переменную fso, вы можете воспользоваться автозаполнением (Intellisense) и открыть для себя другие замечательные функции FileSystemObject.

Вот полный пример модуля:

Option Explicit

' Go to Tools -> References... and check "Microsoft Scripting Runtime" to be able to use
' the FileSystemObject which has many useful features for handling files and folders
Public Sub SaveTextToFile()

    Dim filePath As String
    filePath = "C:\temp\MyTestFile.txt"

    ' The advantage of correctly typing fso as FileSystemObject is to make autocompletion
    ' (Intellisense) work, which helps you avoid typos and lets you discover other useful
    ' methods of the FileSystemObject
    Dim fso As FileSystemObject
    Set fso = New FileSystemObject
    Dim fileStream As TextStream

    ' Here the actual file is created and opened for write access
    Set fileStream = fso.CreateTextFile(filePath)

    ' Write something to the file
    fileStream.WriteLine "something"

    ' Close it, so it is not locked anymore
    fileStream.Close

    ' Here is another great method of the FileSystemObject that checks if a file exists
    If fso.FileExists(filePath) Then
        MsgBox "Yay! The file was created! :D"
    End If

    ' Explicitly setting objects to Nothing should not be necessary in most cases, but if
    ' you're writing macros for Microsoft Access, you may want to uncomment the following
    ' two lines (see https://stackoverflow.com/a/517202/2822719 for details):
    'Set fileStream = Nothing
    'Set fso = Nothing

End Sub

Ответ 5

Dim SaveVar As Object

Sub Main()

    Console.WriteLine("Enter Text")

    Console.WriteLine("")

    SaveVar = Console.ReadLine

    My.Computer.FileSystem.WriteAllText("N:\A-Level Computing\2017!\PPE\SaveFile\SaveData.txt", "Text: " & SaveVar & ", ", True)

    Console.WriteLine("")

    Console.WriteLine("File Saved")

    Console.WriteLine("")

    Console.WriteLine(My.Computer.FileSystem.ReadAllText("N:\A-Level Computing\2017!\PPE\SaveFile\SaveData.txt"))
    Console.ReadLine()

End Sub()