Как я могу урезать пространство в XSLT, не заменяя повторяющиеся пробелы одиночными?

Функция normalize-space заменяет последовательности пробелов на одно пространство и обрезает предоставленную строку. Как я могу обрезать строку без замены пробелов? Существуют запатентованные решения, такие как orcl:left-trim, но я ищу непатентованный.

Пример:

<xsl:value-of select="trim(/Car/Description)"/>

должен поворачиваться

<car>
  <description>  To get more information look at:     www.example.com </description>
</car>

"To get more information look at:     www.example.com"

Ответ 1

Решение, использующее только шаблоны xslt 1.0:

<xsl:variable name="whitespace" select="'&#09;&#10;&#13; '" />

<!-- Strips trailing whitespace characters from 'string' -->
<xsl:template name="string-rtrim">
    <xsl:param name="string" />
    <xsl:param name="trim" select="$whitespace" />

    <xsl:variable name="length" select="string-length($string)" />

    <xsl:if test="$length &gt; 0">
        <xsl:choose>
            <xsl:when test="contains($trim, substring($string, $length, 1))">
                <xsl:call-template name="string-rtrim">
                    <xsl:with-param name="string" select="substring($string, 1, $length - 1)" />
                    <xsl:with-param name="trim"   select="$trim" />
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$string" />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:if>
</xsl:template>

<!-- Strips leading whitespace characters from 'string' -->
<xsl:template name="string-ltrim">
    <xsl:param name="string" />
    <xsl:param name="trim" select="$whitespace" />

    <xsl:if test="string-length($string) &gt; 0">
        <xsl:choose>
            <xsl:when test="contains($trim, substring($string, 1, 1))">
                <xsl:call-template name="string-ltrim">
                    <xsl:with-param name="string" select="substring($string, 2)" />
                    <xsl:with-param name="trim"   select="$trim" />
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$string" />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:if>
</xsl:template>

<!-- Strips leading and trailing whitespace characters from 'string' -->
<xsl:template name="string-trim">
    <xsl:param name="string" />
    <xsl:param name="trim" select="$whitespace" />
    <xsl:call-template name="string-rtrim">
        <xsl:with-param name="string">
            <xsl:call-template name="string-ltrim">
                <xsl:with-param name="string" select="$string" />
                <xsl:with-param name="trim"   select="$trim" />
            </xsl:call-template>
        </xsl:with-param>
        <xsl:with-param name="trim"   select="$trim" />
    </xsl:call-template>
</xsl:template>

Тестовый код:

<ltrim>
    <xsl:call-template name="string-ltrim">
        <xsl:with-param name="string" select="'   &#10;   test  '" />
    </xsl:call-template>
</ltrim>
<rtrim>
    <xsl:call-template name="string-rtrim">
        <xsl:with-param name="string" select="'    &#10;    test  &#10;  '" />
    </xsl:call-template>
</rtrim>
<trim>
    <xsl:call-template name="string-trim">
        <xsl:with-param name="string" select="'    &#10;    test  &#10;  '" />
    </xsl:call-template>
</trim>

Вывод:

<test>
    <ltrim>test  </ltrim>
    <rtrim>   
    test</rtrim>
    <trim>test</trim>
</test>

Ответ 2

Очень короткое решение с XSLT1:

<xsl:template name="trim">
            <xsl:param name="str"/>

            <xsl:choose>
                <xsl:when test="string-length($str) &gt; 0 and substring($str, 1, 1) = ' '">
                    <xsl:call-template name="trim"><xsl:with-param name="str"><xsl:value-of select="substring($str, 2)"/></xsl:with-param></xsl:call-template></xsl:when>
                <xsl:when test="string-length($str) &gt; 0 and substring($str, string-length($str)) = ' '">
                    <xsl:call-template name="trim"><xsl:with-param name="str"><xsl:value-of select="substring($str, 1, string-length($str)-1)"/></xsl:with-param></xsl:call-template></xsl:when>
                <xsl:otherwise><xsl:value-of select="$str"/></xsl:otherwise>
            </xsl:choose>
        </xsl:template>

Ответ 3

Используя FXSL (библиотека с открытым исходным кодом для функционального программирования XSLT, полностью написанная в XSLT), просто пишет

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:import href="trim.xsl"/>

  <xsl:output method="text"/>
  <xsl:template match="/*/description">
    '<xsl:call-template name="trim">
        <xsl:with-param name="pStr" select="."/>
    </xsl:call-template>'
  </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному XML-документу:

<car>
  <description>  To get more information look at:     www.example.com </description>
</car>

выдается желаемый, правильный результат:

'To get more information look at:     www.example.com'

Как работает trim?

Он обрезает левое ведущее пробелы, затем он реверсирует результирующую строку и обрезает ее ведущие пробелы, а затем, наконец, реверсирует результирующую строку.

II. Решение XPath 2.0:

Использование

replace(replace(/*/description, '^\s*(.+?)\s*$', '$1'), '^ .*$', '')

Вот проверка на основе XSLT-2.0:

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     "<xsl:sequence 
      select="replace(replace(/*/description, '^\s*(.+?)\s*$', '$1'), '^ .*$', '')"/>"
 </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному XML-документу (выше), выражение XPath оценивается, и результат этой оценки копируется на вывод:

 "To get more information look at:     www.example.com"

Ответ 4

normalize-space (actualSting) - это сделает это.

Ответ 5

Если у вас нет пробелов в середине, вы можете просто использовать:

translate(/Car/Description,' ','')